[arch-commits] Commit in openal/repos (3 files)
Jan Steffens
heftig at gemini.archlinux.org
Sun Jan 23 23:22:06 UTC 2022
Date: Sunday, January 23, 2022 @ 23:22:05
Author: heftig
Revision: 435026
archrelease: copy trunk to staging-x86_64
Added:
openal/repos/staging-x86_64/
openal/repos/staging-x86_64/PKGBUILD
(from rev 435023, openal/trunk/PKGBUILD)
openal/repos/staging-x86_64/ffmpeg-5.0.diff
(from rev 435023, openal/trunk/ffmpeg-5.0.diff)
-----------------+
PKGBUILD | 77 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
ffmpeg-5.0.diff | 13 +++++++++
2 files changed, 90 insertions(+)
Copied: openal/repos/staging-x86_64/PKGBUILD (from rev 435023, openal/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-01-23 23:22:05 UTC (rev 435026)
@@ -0,0 +1,77 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Jason Chu <jchu at xentac.net>
+
+pkgbase=openal
+pkgname=(openal openal-examples)
+pkgver=1.21.1
+pkgrel=3
+pkgdesc="Cross-platform 3D audio library, software implementation"
+arch=(x86_64)
+url="https://github.com/kcat/openal-soft"
+license=(LGPL)
+depends=(gcc-libs)
+makedepends=(alsa-lib libpulse fluidsynth portaudio jack qt5-base sdl2
+ libsndfile ffmpeg libmysofa git cmake ninja)
+optdepends=('qt5-base: alsoft-config GUI Configurator'
+ 'fluidsynth: MIDI rendering'
+ 'libmysofa: makemhr tool')
+_commit=ae4eacf147e2c2340cc4e02a790df04c793ed0a9 # tags/1.21.1
+source=("git+https://github.com/kcat/openal-soft#commit=$_commit"
+ ffmpeg-5.0.diff)
+sha512sums=('SKIP'
+ '9a2bcc2036799d4ca9d98845b75b4ae03d9f300e4e7ddf20f7b52239e625d3b064728cd48c5dc36862ae63d0a26ecd994aa4a1594b0ff45c93d226a1fe023337')
+
+pkgver() {
+ cd openal-soft
+ git describe --tags | sed 's/^openal-soft-//;s/-/+/g'
+}
+
+prepare() {
+ cd openal-soft
+
+ # Missing include
+ git cherry-pick -n 302e88dbf0f10224a5b87be4ce43b3fdd9d20184
+
+ # https://bugs.archlinux.org/task/72729
+ git cherry-pick -n b7ff1de48efda9ad54e6a3b4c1526722c371e832
+
+ # Fix build with FFmpeg 5.0
+ git apply -3 ../ffmpeg-5.0.diff
+}
+
+build() {
+ cmake -S openal-soft -B build -G Ninja \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_INSTALL_LIBDIR=lib
+ cmake --build build
+}
+
+_pick() {
+ local p="$1" f d; shift
+ for f; do
+ d="$srcdir/$p/${f#$pkgdir/}"
+ mkdir -p "$(dirname "$d")"
+ mv "$f" "$d"
+ rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+ done
+}
+
+package_openal() {
+ provides+=(libopenal.so)
+
+ DESTDIR="$pkgdir" cmake --install build
+ install -Dt "$pkgdir/usr/share/doc/openal" -m644 openal-soft/docs/*
+
+ cd "$pkgdir"
+ _pick examples usr/bin/al{ffplay,hrtf,latency,loopback,multireverb}
+ _pick examples usr/bin/al{play,record,reverb,stream,tonegen}
+}
+
+package_openal-examples() {
+ pkgdesc+=" (example programs)"
+ depends=("openal=$pkgver-$pkgrel" sdl2 libsndfile ffmpeg)
+ optdepends=()
+ mv examples/* "$pkgdir"
+}
Copied: openal/repos/staging-x86_64/ffmpeg-5.0.diff (from rev 435023, openal/trunk/ffmpeg-5.0.diff)
===================================================================
--- staging-x86_64/ffmpeg-5.0.diff (rev 0)
+++ staging-x86_64/ffmpeg-5.0.diff 2022-01-23 23:22:05 UTC (rev 435026)
@@ -0,0 +1,13 @@
+diff --git i/examples/alffplay.cpp w/examples/alffplay.cpp
+index b9739e7b..806ef10c 100644
+--- i/examples/alffplay.cpp
++++ w/examples/alffplay.cpp
+@@ -1804,7 +1804,7 @@ int MovieState::streamComponentOpen(unsigned int stream_index)
+ if(avcodec_parameters_to_context(avctx.get(), mFormatCtx->streams[stream_index]->codecpar))
+ return -1;
+
+- AVCodec *codec{avcodec_find_decoder(avctx->codec_id)};
++ const AVCodec *codec{avcodec_find_decoder(avctx->codec_id)};
+ if(!codec || avcodec_open2(avctx.get(), codec, nullptr) < 0)
+ {
+ std::cerr<< "Unsupported codec: "<<avcodec_get_name(avctx->codec_id)
More information about the arch-commits
mailing list