[arch-commits] Commit in json-c/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jelle van der Waa]

    Date: Friday, January 28, 2022 @ 10:02:16
  Author: jelle
Revision: 435264

archrelease: copy trunk to testing-x86_64

Added:
  json-c/repos/testing-x86_64/
  json-c/repos/testing-x86_64/PKGBUILD
    (from rev 435263, json-c/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: json-c/repos/testing-x86_64/PKGBUILD (from rev 435263, json-c/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-01-28 10:02:16 UTC (rev 435264)
@@ -0,0 +1,51 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at koon.fr>
+# Contributor: congyiwu <congyiwu AT gmail DOT com>
+
+pkgname=json-c
+pkgver=0.15
+pkgrel=3
+pkgdesc="A JSON implementation in C"
+url="https://github.com/json-c/json-c/wiki"
+license=(MIT)
+arch=(x86_64)
+depends=(glibc)
+makedepends=(git cmake ninja)
+provides=(libjson-c.so)
+options=(debug)
+_commit=9021cdcdd01fc9dbcbe1f06391848c2ac915212f  # tags/json-c-0.15-20200726^0
+source=("git+https://github.com/json-c/json-c#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd json-c
+  local tag="$(git describe --tags --abbrev=0)"
+  local ver="$(git describe --tags)"
+  echo "${tag%-*}${ver#$tag}" | sed 's/^json-c-//;s/-/+/g'
+}
+
+prepare() {
+  cd json-c
+}
+
+build() {
+  cmake -S json-c -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+    -DBUILD_STATIC_LIBS=OFF \
+    -DENABLE_THREADING=ON \
+    -DENABLE_RDRAND=OFF
+  cmake --build build
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 json-c/COPYING
+}
+
+# vim:set sw=2 et: