[arch-commits] Commit in qt6-multimedia/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Friday, January 28, 2022 @ 14:12:23
  Author: arojas
Revision: 435300

archrelease: copy trunk to testing-x86_64

Added:
  qt6-multimedia/repos/testing-x86_64/
  qt6-multimedia/repos/testing-x86_64/PKGBUILD
    (from rev 435299, qt6-multimedia/trunk/PKGBUILD)

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Copied: qt6-multimedia/repos/testing-x86_64/PKGBUILD (from rev 435299, qt6-multimedia/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-01-28 14:12:23 UTC (rev 435300)
@@ -0,0 +1,34 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=qt6-multimedia
+_qtver=6.2.3
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Classes for audio, video, radio and camera functionality'
+depends=(qt6-base gst-plugins-base)
+makedepends=(cmake ninja qt6-declarative qt6-shadertools)
+optdepends=('qt6-declarative: QML bindings'
+            'gst-plugins-good: camera support, additional plugins'
+            'gst-plugins-bad: camera support, additional plugins'
+            'gst-plugins-ugly: additional plugins'
+            'gst-libav: ffmpeg plugin')
+groups=(qt6)
+_pkgfn="${pkgname/6-/}-everywhere-src-$_qtver"
+source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
+sha256sums=('d97aa2f3ccb1e3e9f3ebe986a298c2927aa543d2b987c8ec496c452ff61ee687')
+
+build() {
+  cmake -B build -S $_pkgfn -G Ninja
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
+}