[arch-commits] Commit in waylock/repos/community-x86_64 (PKGBUILD PKGBUILD)

[David Runge]

    Date: Friday, January 28, 2022 @ 16:56:17
  Author: dvzrv
Revision: 1118356

archrelease: copy trunk to community-x86_64

Added:
  waylock/repos/community-x86_64/PKGBUILD
    (from rev 1118355, waylock/trunk/PKGBUILD)
Deleted:
  waylock/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   73 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 39 insertions(+), 34 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-01-28 16:56:08 UTC (rev 1118355)
+++ PKGBUILD	2022-01-28 16:56:17 UTC (rev 1118356)
@@ -1,34 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-
-pkgname=waylock
-pkgver=0.3.3
-pkgrel=2
-pkgdesc="A simple screenlocker for wayland compositors"
-arch=('x86_64')
-url="https://github.com/ifreund/waylock"
-license=('MIT')
-depends=('gcc-libs' 'glibc')
-makedepends=('git' 'pam' 'rust')
-_commit=2391ef614783b06ce4b88b14fb4a636fbb2a91a6 # refs/tags/v0.3.3^{}
-source=("git+https://github.com/ifreund/waylock#commit=${_commit}?signed")
-md5sums=('SKIP')
-validpgpkeys=('5FBDF84DD2278DB2B8AD8A5286DED400DDFD7A11') # Isaac Freund <ifreund at ifreund.xyz>
-
-build() {
-  cd "$pkgname"
-  cargo build --release --locked --all-features --target-dir=target
-}
-
-check() {
-  cd "$pkgname"
-  cargo test --release --locked --target-dir=target
-}
-
-package() {
-  depends+=('libpam.so')
-  cd "$pkgname"
-  install -vDm 755 target/release/${pkgname} -t "${pkgdir}/usr/bin"
-  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
-  install -vDm 644 {README.md,waylock.toml} \
-    -t "${pkgdir}/usr/share/doc/${pkgname}"
-}

Copied: waylock/repos/community-x86_64/PKGBUILD (from rev 1118355, waylock/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-01-28 16:56:17 UTC (rev 1118356)
@@ -0,0 +1,39 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=waylock
+pkgver=0.3.4
+_commit=e08829bf6a7b828ecb68a56919e72a35775fb2c3 # refs/tags/v0.3.4^{}
+pkgrel=1
+pkgdesc="A simple screenlocker for wayland compositors"
+arch=(x86_64)
+url="https://github.com/ifreund/waylock"
+license=(MIT)
+depends=(gcc-libs glibc)
+makedepends=(git libxkbcommon pam rust)
+source=("git+https://github.com/ifreund/waylock#commit=${_commit}?signed")
+md5sums=('SKIP')
+validpgpkeys=('5FBDF84DD2278DB2B8AD8A5286DED400DDFD7A11') # Isaac Freund <ifreund at ifreund.xyz>
+
+prepare() {
+  cd "$pkgname"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname"
+  cargo build --frozen --release --all-features --target-dir=target
+}
+
+check() {
+  cd "$pkgname"
+  cargo test --release --locked --target-dir=target
+}
+
+package() {
+  depends+=(libpam.so libxkbcommon.so)
+
+  cd "$pkgname"
+  install -vDm 755 target/release/${pkgname} -t "${pkgdir}/usr/bin"
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -vDm 644 {README.md,waylock.toml} -t "${pkgdir}/usr/share/doc/${pkgname}"
+}