[arch-commits] Commit in accountsservice/repos/extra-x86_64 (3 files)

[Jan Steffens]

    Date: Friday, January 28, 2022 @ 23:25:12
  Author: heftig
Revision: 435328

archrelease: copy trunk to extra-x86_64

Added:
  accountsservice/repos/extra-x86_64/PKGBUILD
    (from rev 435327, accountsservice/trunk/PKGBUILD)
  accountsservice/repos/extra-x86_64/dirmode.diff
    (from rev 435327, accountsservice/trunk/dirmode.diff)
Deleted:
  accountsservice/repos/extra-x86_64/PKGBUILD

--------------+
 PKGBUILD     |  105 +++++++++++++++++++++++++++++----------------------------
 dirmode.diff |   20 ++++++++++
 2 files changed, 75 insertions(+), 50 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-01-28 23:24:43 UTC (rev 435327)
+++ PKGBUILD	2022-01-28 23:25:12 UTC (rev 435328)
@@ -1,50 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Ionut Biru <ibiru at archlinux.org>
-
-pkgname=accountsservice
-pkgver=0.6.55
-pkgrel=3
-pkgdesc="D-Bus interface for user account query and manipulation"
-url="https://gitlab.freedesktop.org/accountsservice/accountsservice"
-arch=(x86_64)
-license=(GPL3)
-depends=(glib2 polkit systemd shadow libxcrypt)
-makedepends=(gtk-doc gobject-introspection git meson docbook-xsl xmlto)
-provides=(libaccountsservice.so)
-_commit=6d6f7d62fd18fe5a4d4c06cb1455887ca3abdd1d  # tags/0.6.55^0
-source=("git+https://gitlab.freedesktop.org/accountsservice/accountsservice.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/-/+/g'
-}
-
-
-prepare() {
-  cd $pkgname
-  sed -i '/dbus_conf_dir/s/sysconfdir/datadir/g' meson.build
-}
-
-build() {
-  arch-meson $pkgname build \
-    -D admin_group=wheel \
-    -D systemd=true \
-    -D docbook=true \
-    -D gtk_doc=true \
-    -D user_heuristics=false
-  meson compile -C build
-}
-
-check() {
-  meson test -C build
-}
-
-package() {
-  DESTDIR="$pkgdir" meson install -C build
-
-  # Fix permissions to match the ones the daemon sets
-  chmod 0775 "$pkgdir/var/lib/AccountsService/icons"
-}
-
-# vim:set ts=2 sw=2 et:

Copied: accountsservice/repos/extra-x86_64/PKGBUILD (from rev 435327, accountsservice/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-01-28 23:25:12 UTC (rev 435328)
@@ -0,0 +1,55 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=accountsservice
+pkgver=22.04.62
+pkgrel=1
+pkgdesc="D-Bus interface for user account query and manipulation"
+url="https://gitlab.freedesktop.org/accountsservice/accountsservice"
+arch=(x86_64)
+license=(GPL3)
+depends=(glib2 polkit systemd shadow libxcrypt)
+makedepends=(gtk-doc gobject-introspection git meson docbook-xsl xmlto vala)
+checkdepends=(python-gobject python-dbusmock)
+_commit=b92982be695700537bf80c5e9aa518820adbb7b6  # tags/22.04.62^0
+source=("git+https://gitlab.freedesktop.org/accountsservice/accountsservice.git#commit=$_commit"
+        dirmode.diff)
+sha256sums=('SKIP'
+            'abb66aa011ac72a28b2e766f5d713028143fb3b642fb7e3ae81bea1b70c9ec26')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+
+prepare() {
+  cd $pkgname
+
+  # Fix permissions to match the ones the daemon sets
+  git apply -3 ../dirmode.diff
+}
+
+build() {
+  local meson_options=(
+    -D admin_group=wheel
+    -D docbook=true
+    -D gtk_doc=true
+  )
+
+  arch-meson $pkgname build "${meson_options[@]}"
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  depends+=(libg{lib,object,io}-2.0.so libsystemd.so libcrypt.so)
+  provides+=(libaccountsservice.so)
+
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim:set sw=2 et:

Copied: accountsservice/repos/extra-x86_64/dirmode.diff (from rev 435327, accountsservice/trunk/dirmode.diff)
===================================================================
--- dirmode.diff	                        (rev 0)
+++ dirmode.diff	2022-01-28 23:25:12 UTC (rev 435328)
@@ -0,0 +1,20 @@
+ meson_post_install.py | 2 ++
+ 1 file changed, 2 insertions(+)
+
+diff --git c/meson_post_install.py i/meson_post_install.py
+index 5cc2dc4..76348a2 100644
+--- c/meson_post_install.py
++++ i/meson_post_install.py
+@@ -9,10 +9,12 @@ localstatedir = os.path.normpath(destdir + os.sep + sys.argv[1])
+ # FIXME: meson will not track the creation of these directories
+ #        https://github.com/mesonbuild/meson/blob/master/mesonbuild/scripts/uninstall.py#L39
+ dst_dirs = [
++  (os.path.join(localstatedir, 'lib', 'AccountsService'), 0o755),
+   (os.path.join(localstatedir, 'lib', 'AccountsService', 'icons'), 0o775),
+   (os.path.join(localstatedir, 'lib', 'AccountsService', 'users'), 0o700),
+ ]
+ 
+ for (dst_dir, dst_dir_mode) in dst_dirs:
+   if not os.path.exists(dst_dir):
++    os.umask(0o777 & ~dst_dir_mode)
+     os.makedirs(dst_dir, mode=dst_dir_mode)