[arch-commits] Commit in foot/repos (2 files)

[Caleb Maclennan]

    Date: Saturday, January 29, 2022 @ 17:12:27
  Author: alerque
Revision: 1119853

archrelease: copy trunk to community-testing-x86_64

Added:
  foot/repos/community-testing-x86_64/
  foot/repos/community-testing-x86_64/PKGBUILD
    (from rev 1119852, foot/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: foot/repos/community-testing-x86_64/PKGBUILD (from rev 1119852, foot/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-01-29 17:12:27 UTC (rev 1119853)
@@ -0,0 +1,67 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Daniel Eklöf <daniel at ekloef dot se>
+
+pkgbase=foot
+pkgdesc='Fast, lightweight, and minimalistic Wayland terminal emulator'
+pkgname=($pkgbase $pkgbase-terminfo)
+pkgver=1.10.3
+pkgrel=3
+url=https://codeberg.org/dnkl/$pkgbase
+arch=(x86_64)
+license=(MIT)
+makedepends=(fcft
+             fontconfig
+             libutf8proc
+             libxkbcommon
+             llvm
+             meson
+             ncurses
+             ninja
+             pixman
+             python
+             scdoc
+             sway
+             tllist
+             wayland
+             wayland-protocols)
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha256sums=('24f57d9926ead7bea491f1bdd97eaceae5fdc10c1cb3435ee588a8f9c9af805a')
+
+build() {
+	cd "$pkgbase"
+	./pgo/pgo.sh \
+		full-headless-sway \
+		. build \
+		--prefix=/usr \
+		--wrap-mode=nodownload
+}
+
+check() {
+	cd "$pkgbase"
+	ninja -C build test
+}
+
+package_foot() {
+	optdepends=('foot-terminfo: alternative to ncurses’ terminfo, with additional non-standard capabilities'
+	            'libnotify: desktop notifications'
+	            'xdg-utils: URI launching')
+	depends=(fcft
+	         fontconfig
+	         libutf8proc
+	         libxkbcommon
+	         ncurses
+	         pixman
+	         wayland)
+	cd "$pkgbase"
+	DESTDIR="$pkgdir" ninja -C build install
+    rm -r "$pkgdir/usr/share/terminfo"
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
+
+package_foot-terminfo() {
+	pkgdesc="Terminfo for $pkgbase, a Wayland terminal emulator"
+	depends=(ncurses)
+	cd "$pkgbase"
+	install -Dm0644 -t "$pkgdir/usr/share/terminfo/f/" build/f/*
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}