[arch-commits] Commit in luajit/repos (2 files)

[Daurnimator]

    Date: Monday, January 31, 2022 @ 14:21:08
  Author: daurnimator
Revision: 1121234

archrelease: copy trunk to community-testing-x86_64

Added:
  luajit/repos/community-testing-x86_64/
  luajit/repos/community-testing-x86_64/PKGBUILD
    (from rev 1121233, luajit/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: luajit/repos/community-testing-x86_64/PKGBUILD (from rev 1121233, luajit/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-01-31 14:21:08 UTC (rev 1121234)
@@ -0,0 +1,37 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Chris Brannon <chris at the-brannons.com>
+# Contributor: Paulo Matias <matiasΘarchlinux-br·org>
+# Contributor: Anders Bergh <anders1 at gmail.com>
+
+pkgname=luajit
+# LuaJIT has abandoned versioned releases and now advises using git HEAD
+# https://github.com/LuaJIT/LuaJIT/issues/665#issuecomment-784452583
+_commit=1d7b5029c5ba36870d25c67524034d452b761d27
+pkgver="2.1.0.beta3.r384.g${_commit::8}"
+pkgrel=1
+pkgdesc='Just-in-time compiler and drop-in replacement for Lua 5.1'
+arch=('x86_64')
+url='https://luajit.org/'
+license=('MIT')
+depends=('gcc-libs')
+options=(debug)
+source=("LuaJIT-${_commit}.tar.gz::https://repo.or.cz/luajit-2.0.git/snapshot/${_commit}.tar.gz")
+md5sums=('c9231846c3a5006826aef8f668a182dd')
+sha256sums=('cbcb73645d48aae0285883c1132a4e7b882b4c9f8d2ecf0ccdcfd795443e186d')
+b2sums=('eb4510c745dd2cb3b6444b434fc70d24088dad2d3a82e4e08d97bafdda075555a564084c850d695958889d39635bfaea1e012737f0cc31c257a62330eda2fdc5')
+
+build() {
+  cd "luajit-2.0-${_commit::7}"
+  # Avoid early stripping
+  make amalg PREFIX=/usr BUILDMODE=dynamic TARGET_STRIP=" @:"
+}
+
+package() {
+  cd "luajit-2.0-${_commit::7}"
+
+  make install DESTDIR="$pkgdir" PREFIX=/usr
+  install -Dm644 COPYRIGHT "$pkgdir/usr/share/licenses/$pkgname/COPYRIGHT"
+
+  ln -sf luajit-2.1.0-beta3 "$pkgdir/usr/bin/luajit"
+}