[arch-commits] Commit in haskell-yesod-test/repos (2 files)

[Felix Yan]

    Date: Monday, January 31, 2022 @ 20:30:07
  Author: felixonmars
Revision: 1121300

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-test/repos/community-staging-x86_64/
  haskell-yesod-test/repos/community-staging-x86_64/PKGBUILD
    (from rev 1121299, haskell-yesod-test/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-yesod-test/repos/community-staging-x86_64/PKGBUILD (from rev 1121299, haskell-yesod-test/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-31 20:30:07 UTC (rev 1121300)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=yesod-test
+pkgname=haskell-yesod-test
+pkgver=1.6.12
+pkgrel=249
+pkgdesc="Integration testing for WAI/Yesod Applications"
+url="https://www.yesodweb.com"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hunit' 'haskell-aeson' 'haskell-attoparsec' 'haskell-blaze-builder'
+         'haskell-blaze-html' 'haskell-case-insensitive' 'haskell-conduit'
+         'haskell-cookie' 'haskell-hspec-core' 'haskell-html-conduit' 'haskell-http-types'
+         'haskell-memory' 'haskell-network' 'haskell-pretty-show' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-xml-conduit' 'haskell-xml-types' 'haskell-yesod-core')
+makedepends=('ghc' 'haskell-yesod-form' 'haskell-hspec' 'haskell-unliftio' 'haskell-unliftio-core')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('777d112d8c5ae77d667da2b8d1ed91a1cf751850d5b3678e787e7123aca8666d0a4b6d6161b7109491012d56c160603d62563b881a136ccc76a1edd006c423d6')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}