[arch-commits] Commit in openbabel/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, July 7, 2022 @ 18:04:36
  Author: arojas
Revision: 450497

archrelease: copy trunk to staging-x86_64

Added:
  openbabel/repos/staging-x86_64/
  openbabel/repos/staging-x86_64/PKGBUILD
    (from rev 450496, openbabel/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: openbabel/repos/staging-x86_64/PKGBUILD (from rev 450496, openbabel/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-07-07 18:04:36 UTC (rev 450497)
@@ -0,0 +1,39 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Damir Perisa <damir.perisa at bluewin.ch>
+
+pkgbase=openbabel
+pkgname=(openbabel python-openbabel)
+pkgver=3.1.1
+pkgrel=4
+pkgdesc='A library designed to interconvert between many file formats used in molecular modeling and computational chemistry'
+arch=(x86_64)
+url='https://openbabel.org/wiki/Main_Page'
+license=(GPL)
+makedepends=(cmake eigen wxwidgets-gtk3 boost python swig maeparser rapidjson coordgen)
+source=(https://github.com/openbabel/openbabel/releases/download/openbabel-${pkgver//./-}/openbabel-$pkgver-source.tar.bz2)
+sha256sums=('a6ec8381d59ea32a4b241c8b1fbd799acb52be94ab64cdbd72506fb4e2270e68')
+
+build() {
+  cmake -B build -S openbabel-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DRUN_SWIG=ON \
+    -DPYTHON_BINDINGS=ON
+  cmake --build build
+
+  # To split python bindings
+  sed -i '/scripts.cmake_install.cmake/d' build/cmake_install.cmake
+}
+
+package_openbabel() {
+  depends=(libxml2 libsm coordgen)
+  optdepends=('wxwidgets-gtk3: GUI interface')
+
+  DESTDIR="$pkgdir" cmake --install build
+}
+
+package_python-openbabel() {
+  depends=(python openbabel)
+
+  DESTDIR="$pkgdir" cmake --install build/scripts
+}