[arch-commits] Commit in lib32-fluidsynth/repos (2 files)

[David Runge]

    Date: Sunday, July 10, 2022 @ 16:47:26
  Author: dvzrv
Revision: 1249318

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-fluidsynth/repos/multilib-staging-x86_64/
  lib32-fluidsynth/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1249317, lib32-fluidsynth/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: lib32-fluidsynth/repos/multilib-staging-x86_64/PKGBUILD (from rev 1249317, lib32-fluidsynth/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-07-10 16:47:26 UTC (rev 1249318)
@@ -0,0 +1,67 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: David Runge <dvzrv at archlinux.org>
+# Contributor: carstene1ns <arch.carsten at teibes.de>
+# Contributor: Giuseppe Calà  <jiveaxe at gmail.com>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+pkgname=lib32-fluidsynth
+_name=fluidsynth
+pkgver=2.2.8
+pkgrel=1
+pkgdesc='A real-time software synthesizer based on the SoundFont 2 specifications'
+arch=(x86_64)
+url="https://www.fluidsynth.org/"
+license=(LGPL2.1)
+depends=(
+  fluidsynth=${pkgver}
+  lib32-glibc
+  lib32-libpulse
+  lib32-readline
+  lib32-sdl2
+)
+makedepends=(
+  cmake
+  lib32-alsa-lib
+  lib32-dbus
+  lib32-glib2
+  lib32-jack
+  lib32-ladspa
+  lib32-libinstpatch
+  lib32-libsndfile
+  lib32-portaudio
+)
+optdepends=('pulseaudio: PulseAudio sound support')
+options=(debug)
+source=($pkgname-$pkgver.tar.gz::https://github.com/$_name/$_name/archive/v$pkgver.tar.gz)
+sha512sums=('8173f2d368a214cf1eb7faae2f6326db43fb094ec9c83e652f953290c3f29c34ebd0b92cbb439bea8d814d3a7e4f9dc0c18c648df1d414989d5d8b4700c79535')
+b2sums=('7eaee4cc1c2f49e464cda2852890ec8e96bd86c258a39246ec5c84ea3e57c9869d1e88963daecc3fa8957df1d55ff6c6633a4900de3d6fc0a1adf830865adda0')
+
+build() {
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=None \
+        -DFLUID_DAEMON_ENV_FILE=/etc/conf.d/fluidsynth \
+        -DLIB_SUFFIX=32 \
+        -Denable-ladspa=ON \
+        -Denable-portaudio=ON \
+        -Wno-dev \
+        -B build \
+        -S $_name-$pkgver
+  make -C build VERBOSE=1
+}
+
+check() {
+  make -C build -k check
+}
+
+package() {
+  depends+=(libasound.so libglib-2.0.so libgmodule-2.0.so libgobject-2.0.so
+  libinstpatch-1.0.so libjack.so libportaudio.so libsndfile.so)
+
+  make -C build DESTDIR="$pkgdir" install
+  rm -rf "$pkgdir"/usr/{include,share,bin}
+}
+# vim: ts=2 sw=2 et: