[arch-commits] Commit in filezilla/repos (3 files)

Antonio Rojas arojas at gemini.archlinux.org
Mon Jul 11 17:04:41 UTC 2022


    Date: Monday, July 11, 2022 @ 17:04:41
  Author: arojas
Revision: 1249596

archrelease: copy trunk to community-staging-x86_64

Added:
  filezilla/repos/community-staging-x86_64/
  filezilla/repos/community-staging-x86_64/PKGBUILD
    (from rev 1249595, filezilla/trunk/PKGBUILD)
  filezilla/repos/community-staging-x86_64/wxwidgets-3.2.patch
    (from rev 1249595, filezilla/trunk/wxwidgets-3.2.patch)

---------------------+
 PKGBUILD            |   45 +++++++++++++++++++++++++++++++++++++++++++++
 wxwidgets-3.2.patch |   27 +++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

Copied: filezilla/repos/community-staging-x86_64/PKGBUILD (from rev 1249595, filezilla/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-07-11 17:04:41 UTC (rev 1249596)
@@ -0,0 +1,45 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+pkgname=filezilla
+pkgver=3.60.1
+pkgrel=2
+pkgdesc='Fast and reliable FTP, FTPS and SFTP client'
+url='https://filezilla-project.org/'
+arch=('x86_64')
+license=('GPL')
+depends=(
+  'dbus' 'xdg-utils' 'wxwidgets-gtk3' 'libidn' 'hicolor-icon-theme' 'sqlite'
+  'gnutls' 'libfilezilla'
+  libfilezilla.so libdbus-1.so libgtk-3.so libgdk-3.so libnettle.so
+)
+source=(https://download.filezilla-project.org/client/FileZilla_${pkgver}_src.tar.bz2
+        wxwidgets-3.2.patch)
+sha256sums=('81f96c63638caf1838e0c63e5874f60192120965d825294a894a22b7d42066af'
+            'e77564b7c21a443f52dd7cb4fa4b8d1519396b241414fe6ee95feca6e143d748')
+sha512sums=('417b97afd8e9434c625392c4025ab7d977d58fad2dfe17c8ff856233c70b5d77df22c4e1b76120d9d5dba3bce1c61453808deb26314dbde7ec425d643c4f83d9'
+            'd31eb0da71cbc740e6210435f97920caac6c26be98717b656c785df6be248fa27925495fa90b118dcbc582ac32af957472cbbe16fdb4fef0bbc6257d15d06931')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  patch -p1 < ../wxwidgets-3.2.patch # Allow building with wxWidgets 3.2
+  autoreconf -vif
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --disable-manualupdatecheck \
+    --disable-autoupdatecheck \
+    --with-pugixml=builtin
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+}
+
+# vim: ts=2 sw=2 et:

Copied: filezilla/repos/community-staging-x86_64/wxwidgets-3.2.patch (from rev 1249595, filezilla/trunk/wxwidgets-3.2.patch)
===================================================================
--- community-staging-x86_64/wxwidgets-3.2.patch	                        (rev 0)
+++ community-staging-x86_64/wxwidgets-3.2.patch	2022-07-11 17:04:41 UTC (rev 1249596)
@@ -0,0 +1,27 @@
+diff -ru filezilla-3.60.1.orig/configure.ac filezilla-3.60.1/configure.ac
+--- filezilla-3.60.1.orig/configure.ac	2022-07-07 23:16:56.929350754 +0200
++++ filezilla-3.60.1/configure.ac	2022-07-11 19:02:07.212006501 +0200
+@@ -185,11 +185,6 @@
+         equivalent variable and wxWidgets version is $MIN_WX_VERSION or above.
+     ])
+   fi
+-  if test "${WX_VERSION_MAJOR}.${WX_VERSION_MINOR}" = "3.1"; then
+-    AC_MSG_ERROR([You must use wxWidgets 3.0.x, development versions of wxWidgets are not supported.])
+-  elif test "${WX_VERSION_MAJOR}.${WX_VERSION_MINOR}" != "3.0"; then
+-    AC_MSG_ERROR([You must use wxWidgets 3.0.x, wxWidgets 3.2 or higher is not yet supported.])
+-  fi
+   
+   if test "${WX_VERSION_MAJOR}.${WX_VERSION_MINOR}" = "3.0"; then
+     MAC_REQUIRES_AQUA="YES"
+diff -ru filezilla-3.60.1.orig/src/interface/search.h filezilla-3.60.1/src/interface/search.h
+--- filezilla-3.60.1.orig/src/interface/search.h	2022-07-07 23:16:56.962684362 +0200
++++ filezilla-3.60.1/src/interface/search.h	2022-07-11 19:01:24.584985318 +0200
+@@ -13,7 +13,7 @@
+ class CSearchDialogFileList;
+ class CWindowStateManager;
+ 
+-class CSearchDialog final : protected CFilterConditionsDialog, public CStateEventHandler
++class CSearchDialog final : public CFilterConditionsDialog, public CStateEventHandler
+ {
+ 	friend class CSearchDialogFileList;
+ public:



More information about the arch-commits mailing list