[arch-commits] Commit in python-starlette/repos (2 files)

[David Runge]

    Date: Tuesday, July 12, 2022 @ 10:53:29
  Author: dvzrv
Revision: 1250385

archrelease: copy trunk to community-staging-any

Added:
  python-starlette/repos/community-staging-any/
  python-starlette/repos/community-staging-any/PKGBUILD
    (from rev 1250384, python-starlette/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-starlette/repos/community-staging-any/PKGBUILD (from rev 1250384, python-starlette/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2022-07-12 10:53:29 UTC (rev 1250385)
@@ -0,0 +1,55 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+
+_name=starlette
+pkgname=python-$_name
+pkgver=0.20.4
+pkgrel=1
+pkgdesc='The little ASGI framework that shines'
+arch=(any)
+url="https://github.com/encode/starlette"
+license=(BSD)
+depends=(python python-anyio)
+optdepends=(
+  'python-itsdangerous: for session middleware support'
+  'python-jinja: for jinja templates'
+  'python-python-multipart: for form parsing'
+  'python-pyyaml: for schema generator'
+  'python-requests: for test client'
+)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(
+  python-aiosqlite
+  python-databases
+  python-pytest
+  python-trio
+
+  # optdepends
+  python-itsdangerous
+  python-jinja
+  python-python-multipart
+  python-pyyaml
+  python-requests
+
+  # not specified,but required
+  python-sqlalchemy
+)
+source=($_name-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz)
+sha512sums=('481a095ada3140164abae89026da36c90657d8ccabb0a6753094bf7fdf47ce6f789320ed15e94d15dedffaf302691e204cb541c26a4c779848aa6505dfe52b2f')
+b2sums=('265ef6b88ebc5cee4361601198891cbab9e92e354942a06622bdac46dc63d2644557bef952730b455157ee83b15035016039f8a88f17e673487e9a3571d6180c')
+
+build() {
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd $_name-$pkgver
+  pytest -vv -o 'markers=filterwarnings' -p no:warnings
+}
+
+package() {
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname/"
+}