[arch-commits] Commit in ruby-bundler/repos (2 files)

[George Rawlinson]

    Date: Tuesday, July 12, 2022 @ 17:57:21
  Author: grawlinson
Revision: 1250749

archrelease: copy trunk to community-testing-any

Added:
  ruby-bundler/repos/community-testing-any/
  ruby-bundler/repos/community-testing-any/PKGBUILD
    (from rev 1250748, ruby-bundler/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: ruby-bundler/repos/community-testing-any/PKGBUILD (from rev 1250748, ruby-bundler/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2022-07-12 17:57:21 UTC (rev 1250749)
@@ -0,0 +1,55 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Jonne Haß <me at jhass.eu>
+# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux at free.fr>
+# Contributor: Anatol Pomozov <anatol.pomozov at gmail.com>
+# Contributor: Alexsandr Pavlov <kidoz at mail dot ru>
+
+pkgname=ruby-bundler
+_gemname="${pkgname#ruby-}"
+pkgver=2.3.17
+pkgrel=1
+pkgdesc="Manages an application's dependencies through its entire life, across many machines, systematically and repeatably"
+arch=('any')
+url='https://bundler.io'
+license=('MIT')
+depends=('ruby' 'rubygems')
+makedepends=('git' 'ruby-rdoc' 'ruby-rake')
+options=('!emptydirs')
+_commit='539b20c172a16904aa7290ea90cd2114c910cec2'
+source=("$pkgname::git+https://github.com/rubygems/rubygems#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed -e 's/^bundler-v//'
+}
+
+build() {
+  cd "$pkgname/bundler"
+
+  rake build
+}
+
+package() {
+  local _gemdir="$(gem env gemdir)"
+
+  gem install \
+    --ignore-dependencies \
+    --no-user-install \
+    --install-dir "$pkgdir/$_gemdir" \
+    --bindir "$pkgdir/usr/bin" \
+    "$pkgname/bundler/pkg/$_gemname-$pkgver.gem"
+
+  # remove unreproducible/unnecessary files
+  rm -vrf "$pkgdir/$_gemdir/cache"
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/LICENSE.md"
+
+  # move man pages
+  install -vd "$pkgdir/usr/share/man/"{man1,man5}
+  mv -vt "$pkgdir/usr/share/man/man1" "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/lib/bundler/man"/*.1
+  mv -vt "$pkgdir/usr/share/man/man5" "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/lib/bundler/man"/*.5
+}