[arch-commits] Commit in haskell-hledger-lib/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 12, 2022 @ 20:18:56
  Author: felixonmars
Revision: 1251299

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hledger-lib/repos/community-staging-x86_64/
  haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD
    (from rev 1251298, haskell-hledger-lib/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD (from rev 1251298, haskell-hledger-lib/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-07-12 20:18:56 UTC (rev 1251299)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hledger-lib
+pkgname=haskell-hledger-lib
+pkgver=1.25
+pkgrel=42
+pkgdesc="A reusable library providing the core functionality of hledger"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-ansi-terminal'
+         'haskell-blaze-markup' 'haskell-call-stack' 'haskell-cassava' 'haskell-cassava-megaparsec'
+         'haskell-cmdargs' 'haskell-data-default' 'haskell-decimal' 'haskell-doclayout'
+         'haskell-extra' 'haskell-file-embed' 'haskell-glob' 'haskell-hashtables'
+         'haskell-megaparsec' 'haskell-microlens' 'haskell-microlens-th'
+         'haskell-parser-combinators' 'haskell-pretty-simple' 'haskell-regex-tdfa' 'haskell-safe'
+         'haskell-tabular' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-timeit' 'haskell-uglymemo'
+         'haskell-unordered-containers' 'haskell-utf8-string')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('cab8a307b58785dacee0b3a76eb9b45dcbefb180a811bf6ab6f93fde9dcedd7c99c2aa4e08f3cdbf1da9d2716a81958d433432245bf520551ec6d7857b6b7f1a')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u doclayout -u megaparsec $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}