[arch-commits] Commit in gtk-vnc/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Thursday, July 14, 2022 @ 23:05:55
  Author: heftig
Revision: 451078

archrelease: copy trunk to extra-x86_64

Added:
  gtk-vnc/repos/extra-x86_64/PKGBUILD
    (from rev 451076, gtk-vnc/trunk/PKGBUILD)
Deleted:
  gtk-vnc/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   95 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 48 insertions(+), 47 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-07-14 23:05:53 UTC (rev 451077)
+++ PKGBUILD	2022-07-14 23:05:55 UTC (rev 451078)
@@ -1,47 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Jan de Groot <jgc at archlinux.org>
-# Contributor: Allan McRae <mcrae_allan at hotmail.com>
-# Contributor: lp76 <l.peduto at gmail.com>
-
-pkgname=gtk-vnc
-pkgver=1.3.0
-pkgrel=1
-pkgdesc="A VNC viewer widget for GTK+"
-url="https://wiki.gnome.org/Projects/gtk-vnc"
-arch=(x86_64)
-license=(LGPL)
-depends=(libgcrypt gtk3 gnutls libpulse)
-makedepends=(vala gobject-introspection git perl-text-csv meson)
-provides=(libgtk-vnc-2.0.so libgvnc{,pulse}-1.0.so)
-_commit=3df186523a8eab9ff6cbbcb2e23d5d8986461c2e  # tags/v1.3.0^0
-source=("git+https://gitlab.gnome.org/GNOME/gtk-vnc.git#commit=$_commit"
-        git+https://gitlab.com/keycodemap/keycodemapdb.git)
-sha256sums=('SKIP'
-            'SKIP')
-
-pkgver() {
-  cd gtk-vnc
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  cd gtk-vnc
-
-  git submodule init
-  git submodule set-url src/keycodemapdb "$srcdir/keycodemapdb"
-  git submodule update
-}
-
-build() {
-  arch-meson gtk-vnc build
-  meson compile -C build
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-package() {
-  meson install -C build --destdir "$pkgdir"
-  install -Dt "$pkgdir/usr/bin" build/examples/gvncviewer
-}

Copied: gtk-vnc/repos/extra-x86_64/PKGBUILD (from rev 451076, gtk-vnc/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-07-14 23:05:55 UTC (rev 451078)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Allan McRae <mcrae_allan at hotmail.com>
+# Contributor: lp76 <l.peduto at gmail.com>
+
+pkgname=gtk-vnc
+pkgver=1.3.1
+pkgrel=1
+pkgdesc="VNC viewer widget for GTK"
+url="https://wiki.gnome.org/Projects/gtk-vnc"
+arch=(x86_64)
+license=(LGPL)
+depends=(libgcrypt gtk3 gnutls libpulse)
+makedepends=(vala gobject-introspection git perl-text-csv meson)
+provides=(libgtk-vnc-2.0.so libgvnc{,pulse}-1.0.so)
+options=(debug)
+_commit=1ea35aa11bdf97916409504024bcd36a01abc64d  # tags/v1.3.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gtk-vnc.git#commit=$_commit"
+        "git+https://gitlab.com/keycodemap/keycodemapdb.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd gtk-vnc
+  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd gtk-vnc
+
+  git submodule init
+  git submodule set-url src/keycodemapdb "$srcdir/keycodemapdb"
+  git submodule update
+}
+
+build() {
+  arch-meson gtk-vnc build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+  install -Dt "$pkgdir/usr/bin" build/examples/gvncviewer
+}