[arch-commits] Commit in gtksourceview3/repos (2 files)

[Jan Steffens]

    Date: Monday, July 18, 2022 @ 18:47:44
  Author: heftig
Revision: 1254444

archrelease: copy trunk to community-x86_64

Added:
  gtksourceview3/repos/community-x86_64/
  gtksourceview3/repos/community-x86_64/PKGBUILD
    (from rev 1254443, gtksourceview3/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: gtksourceview3/repos/community-x86_64/PKGBUILD (from rev 1254443, gtksourceview3/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2022-07-18 18:47:44 UTC (rev 1254444)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gtksourceview3
+pkgver=3.24.11+28+g73e57b57
+pkgrel=1
+pkgdesc="A text widget adding syntax highlighting and more to GNOME"
+url="https://wiki.gnome.org/Projects/GtkSourceView"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libxml2)
+makedepends=(intltool gobject-introspection vala gtk-doc autoconf-archive
+             yelp-tools git)
+checkdepends=(xorg-server-xvfb)
+_commit=73e57b5787ac60776c57032e05a4cc32207f9cf6  # gnome-3-24
+source=("git+https://gitlab.gnome.org/GNOME/gtksourceview.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gtksourceview
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd gtksourceview
+
+  # Workaround incompat with recent autoconf-archive
+  find . -name Makefile.am -exec sed -i '/@CODE_COVERAGE_RULES@/d' {} +
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd gtksourceview
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --disable-glade-catalog --enable-gtk-doc --disable-Werror
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd gtksourceview
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    make check
+}
+
+package() {
+  cd gtksourceview
+  make DESTDIR="$pkgdir" install
+}