[arch-commits] Commit in rtkit/repos/extra-x86_64 (PKGBUILD PKGBUILD keys)

[Jan Steffens]

    Date: Monday, July 18, 2022 @ 19:22:13
  Author: heftig
Revision: 451457

archrelease: copy trunk to extra-x86_64

Added:
  rtkit/repos/extra-x86_64/PKGBUILD
    (from rev 451454, rtkit/trunk/PKGBUILD)
  rtkit/repos/extra-x86_64/keys/
Deleted:
  rtkit/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   89 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 45 insertions(+), 44 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-07-18 19:22:12 UTC (rev 451456)
+++ PKGBUILD	2022-07-18 19:22:13 UTC (rev 451457)
@@ -1,44 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Corrado Primier <bardo at aur.archlinux.org>
-
-pkgname=rtkit
-pkgver=0.13
-pkgrel=1
-pkgdesc="Realtime Policy and Watchdog Daemon"
-arch=(x86_64)
-url="https://github.com/heftig/rtkit"
-license=(GPL3 'custom:BSD')
-depends=(dbus polkit systemd)
-makedepends=(git meson vim)
-_commit=b9169402fe5e82d20efb754509eb0b191f214599  # tags/v0.13^0
-source=("git+https://github.com/heftig/rtkit?signed#commit=$_commit")
-sha256sums=('SKIP')
-validpgpkeys=('8218F88849AAC522E94CF470A5E9288C4FA415FA')  # Jan Alexander Steffens (heftig)
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-}
-
-build() {
-  arch-meson $pkgname build -D installed_tests=false
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-package() {
-  DESTDIR="$pkgdir" meson install -C build
-
-  echo 'u rtkit 133 "RealtimeKit" /proc' |
-    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
-
-  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/LICENSE
-  sed -ne '4,25p' $pkgname/rtkit.c |
-    install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/COPYING"
-}

Copied: rtkit/repos/extra-x86_64/PKGBUILD (from rev 451454, rtkit/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-07-18 19:22:13 UTC (rev 451457)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Corrado Primier <bardo at aur.archlinux.org>
+
+pkgname=rtkit
+pkgver=0.13
+pkgrel=2
+pkgdesc="Realtime Policy and Watchdog Daemon"
+url="https://github.com/heftig/rtkit"
+arch=(x86_64)
+license=(GPL3 custom:BSD)
+depends=(dbus polkit systemd)
+makedepends=(git meson vim)
+options=(debug)
+_commit=b9169402fe5e82d20efb754509eb0b191f214599  # tags/v0.13^0
+source=("git+https://github.com/heftig/rtkit?signed#commit=$_commit")
+sha256sums=('SKIP')
+validpgpkeys=('8218F88849AAC522E94CF470A5E9288C4FA415FA')  # Jan Alexander Steffens (heftig)
+
+pkgver() {
+  cd rtkit
+  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd rtkit
+}
+
+build() {
+  arch-meson rtkit build -D installed_tests=false
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+
+  echo 'u rtkit 133 "RealtimeKit" /proc' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/rtkit.conf"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 rtkit/LICENSE
+  sed -ne '4,25p' rtkit/rtkit.c |
+    install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}