[arch-commits] Commit in molecule-docker/trunk (PKGBUILD)

[David Runge]

    Date: Tuesday, July 19, 2022 @ 21:54:21
  Author: dvzrv
Revision: 1254762

upgpkg: molecule-docker 2.0.0-1: Upgrade to 2.0.0.

Remove unneeded quotes and curly braces.
Deselect and report failing test.
Switch to PEP517.

Modified:
  molecule-docker/trunk/PKGBUILD

----------+
 PKGBUILD |   55 ++++++++++++++++++++++---------------------------------
 1 file changed, 22 insertions(+), 33 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-07-19 21:49:35 UTC (rev 1254761)
+++ PKGBUILD	2022-07-19 21:54:21 UTC (rev 1254762)
@@ -1,49 +1,38 @@
 # Maintainer: David Runge <dvzrv at archlinux.org>
 
 pkgname=molecule-docker
-pkgver=1.1.0
-pkgrel=2
+pkgver=2.0.0
+pkgrel=1
 pkgdesc="Molecule Docker Driver"
-arch=('any')
+arch=(any)
 url="https://github.com/ansible-community/molecule-docker"
-license=('MIT')
-depends=('molecule' 'python-ansible-compat' 'python-docker' 'python-selinux')
-makedepends=('python-setuptools-scm' 'python-setuptools-scm-git-archive')
-checkdepends=('python-pytest' 'python-pytest-helpers-namespace')
-optdepends=('docker: for using a local docker setup')
-source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/${pkgname}/${pkgname}-${pkgver}.tar.gz")
-sha512sums=('1133883f7f46f08d92051c8387bca048959a06d742dba94d4e6784587194619407744f3e5bea0d883cf78d2919448f4572cdf62f7c537dd4bd0845cec8e3f7b6')
-b2sums=('b2dc53d49bc97ff11a3372f39351e37418439033e4647c02ca0c84e712d6911d65e29266738e372978867d255ae3da0b9758365cb5a3e56dc39284299921f398')
+license=(MIT)
+depends=(molecule python-ansible-compat python-docker python-requests python-selinux)
+makedepends=(python-build python-installer python-pip python-setuptools-scm python-setuptools-scm-git-archive python-wheel)
+checkdepends=(ansible-core python-filelock python-pytest python-pytest-helpers-namespace)
+optdepends=(
+  'docker: for using a local docker setup'
+)
+source=(https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz)
+sha512sums=('adc3367b58110da78876522865b268de866b5f0fead6de31c79c61357a83b1dc927190a2016ee7cc608c318c65e5e287ec2edd5278c15e622e06f6a14dac5b60')
+b2sums=('854eb8a519bad49f560acc91811dbb4fd0a5c50e727e369e89126ddf4159af3bca50528acc1945c6ea5602cc6169d4676c65c05ee27587523dbf017369a01b8f')
 
-prepare() {
-  cd "$pkgname-$pkgver"
-  # remove additional pytest options
-  # remove fitler to raise warnings as errors: https://github.com/ansible-community/molecule/issues/3004
-  sed -e '/pre-commit/d' \
-      -e '/addopts/d' \
-      -e '/error/d' \
-      -i setup.cfg
-
-  printf "from setuptools import setup\nsetup()\n" > setup.py
-}
-
 build() {
-  cd "$pkgname-$pkgver"
-  python setup.py build
+  cd $pkgname-$pkgver
+  export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+  python -m build --wheel --no-isolation
 }
 
 check() {
-  cd "$pkgname-$pkgver"
-  export PYTHONPATH="build:${PYTHONPATH}"
+  cd $pkgname-$pkgver
   # disable tests that require the driver to be installed for the system
   # version of molecule that we are testing with
-  pytest -v --ignore "src/molecule_docker/test/test_func.py"
+  pytest -c /dev/null -vv --ignore "src/molecule_docker/test/test_func.py"
 }
 
 package() {
-  cd "$pkgname-$pkgver"
-  python setup.py install --optimize=1 --root="${pkgdir}"
-  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
-  install -vDm 644 README.rst \
-    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  cd $pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 README.rst -t "$pkgdir/usr/share/doc/$pkgname"
 }