[arch-commits] Commit in lv2/trunk (4 files)
David Runge
dvzrv at gemini.archlinux.org
Wed Jul 20 11:04:42 UTC 2022
Date: Wednesday, July 20, 2022 @ 11:04:42
Author: dvzrv
Revision: 1254860
upgpkg: lv2 1.18.6-1: Upgrade to 1.18.6.
Switch to meson as build system (yay).
Clean up makedepends and optdepends (remove gtk2).
Added:
lv2/trunk/keys/
lv2/trunk/keys/pgp/
lv2/trunk/keys/pgp/907D226E7E13FA337F014A083672782A9BF368F3.asc
Modified:
lv2/trunk/PKGBUILD
-------------------------------------------------------+
PKGBUILD | 74 ++++++----------
keys/pgp/907D226E7E13FA337F014A083672782A9BF368F3.asc | 1
2 files changed, 31 insertions(+), 44 deletions(-)
Modified: PKGBUILD
===================================================================
--- PKGBUILD 2022-07-20 11:00:07 UTC (rev 1254859)
+++ PKGBUILD 2022-07-20 11:04:42 UTC (rev 1254860)
@@ -2,71 +2,57 @@
# Contributor: Ray Rashif <schiv at archlinux.org>
pkgname=lv2
-pkgver=1.18.4
-pkgrel=2
+pkgver=1.18.6
+pkgrel=1
pkgdesc="Plugin standard for audio systems"
arch=(x86_64)
url="https://lv2plug.in/"
license=(ISC)
-makedepends=(asciidoc doxygen gtk2 libsndfile pygmentize
-python-markdown python-pygments python-rdflib waf)
+makedepends=(
+ asciidoc
+ codespell
+ doxygen
+ flake8
+ libsndfile
+ meson
+ pygmentize
+ python-black
+ python-lxml
+ python-markdown
+ python-pygments
+ python-pylint
+ python-rdflib
+ serd
+ sord
+)
optdepends=(
'sord: for lv2_validate'
'libsndfile: for eg-sampler.lv2'
- 'atk: for eg-sampler.lv2 and eg-scope.lv2'
- 'cairo: for eg-sampler.lv2 and eg-scope.lv2'
- 'fontconfig: for eg-sampler.lv2 and eg-scope.lv2'
- 'freetype2: for eg-sampler.lv2 and eg-scope.lv2'
- 'glib2: for eg-sampler.lv2 and eg-scope.lv2'
- 'gtk2: for eg-sampler.lv2 and eg-scope.lv2'
- 'harfbuzz: for eg-sampler.lv2 and eg-scope.lv2'
- 'pango: for eg-sampler.lv2 and eg-scope.lv2'
+ 'python-lxml: for lv2specgen.py'
+ 'python-markdown: for lv2specgen.py'
'python-pygments: for lv2specgen.py'
'python-rdflib: for lv2specgen.py'
)
options=(debug)
-source=(https://lv2plug.in/spec/$pkgname-$pkgver.tar.bz2{,.sig})
-sha512sums=('8095a1f3dcf70cf8cefff18c40b52c1dffeab0fe1f6bfb083c9f0e48a9617d3c8647b3f4db567ac1f5f33564399ffe1023774ad9bacb1bb0133f182422f22d6a'
+source=(https://lv2plug.in/spec/$pkgname-$pkgver.tar.xz{,.sig})
+sha512sums=('baecef70abe8354bca056d67085657e2174e39d2030a5173a226ee194c96662d6c3351df4500b4631e08798765dfed6d758b6be16a2ea78c4f29abb53c5d786f'
'SKIP')
-b2sums=('84bcb5578110ff933b37b398029ed062c9393e17f17ddaa6329638f3c71e2b17b424f84987c00bc2c5699ffc15649362b98d5b238521e593c578c67450ecfeec'
+b2sums=('27c9eb3e15e4515a63f93552c8924c502f8bc585fbf62a62a1fca4ff7fd2e9940827cda4b5c7cbb6858324e1dba5bcad2ad75239da9f860db56e6839224ae186'
'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d at drobilla.net>
-prepare() {
- cd $pkgname-$pkgver
- # let wscript(s) find the custom waf scripts
- mkdir -pv tools
- touch __init__.py
- cp -v waflib/extras/{autowaf,lv2}.py tools/
- mkdir -pv plugins/tools/
- cp -v waflib/extras/{autowaf,lv2}.py plugins/tools/
- rm -rv waflib
- sed -e 's/waflib.extras/tools/g' \
- -e "s/load('autowaf'/load('autowaf', tooldir='tools'/g" \
- -e "s/load('lv2'/load('lv2', tooldir='tools'/g" \
- -i {,plugins/,plugins/*/}wscript
-}
-
build() {
- export LINKFLAGS="$LDFLAGS"
-
- cd $pkgname-$pkgver
- waf configure --prefix=/usr \
- --libdir=/usr/lib \
- --docs \
- --test
- waf -v build $MAKEFLAGS
+ arch-meson $pkgname-$pkgver build
+ meson compile -C build
}
check() {
- cd $pkgname-$pkgver
- waf test
+ meson test -C build
}
package() {
- cd $pkgname-$pkgver
- waf install --destdir="$pkgdir"
- install -vDm 644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
- install -vDm 644 {NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
+ meson install -C build --destdir "$pkgdir"
+ install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
+ install -vDm 644 $pkgname-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
}
# vim:set ts=2 sw=2 et:
Added: keys/pgp/907D226E7E13FA337F014A083672782A9BF368F3.asc
===================================================================
(Binary files differ)
Index: lv2/trunk/keys/pgp/907D226E7E13FA337F014A083672782A9BF368F3.asc
===================================================================
--- keys/pgp/907D226E7E13FA337F014A083672782A9BF368F3.asc 2022-07-20 11:00:07 UTC (rev 1254859)
+++ keys/pgp/907D226E7E13FA337F014A083672782A9BF368F3.asc 2022-07-20 11:04:42 UTC (rev 1254860)
Property changes on: lv2/trunk/keys/pgp/907D226E7E13FA337F014A083672782A9BF368F3.asc
___________________________________________________________________
Added: svn:mime-type
## -0,0 +1 ##
+application/pgp-keys
\ No newline at end of property
More information about the arch-commits
mailing list