[arch-commits] Commit in sord/repos (3 files)

[David Runge]

    Date: Wednesday, July 20, 2022 @ 11:27:59
  Author: dvzrv
Revision: 1254865

archrelease: copy trunk to community-staging-x86_64

Added:
  sord/repos/community-staging-x86_64/
  sord/repos/community-staging-x86_64/PKGBUILD
    (from rev 1254864, sord/trunk/PKGBUILD)
  sord/repos/community-staging-x86_64/keys/

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: sord/repos/community-staging-x86_64/PKGBUILD (from rev 1254864, sord/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-07-20 11:27:59 UTC (rev 1254865)
@@ -0,0 +1,59 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: speps <speps at aur dot archlinux dot org>
+
+pkgbase=sord
+pkgname=(sord sord-docs)
+pkgver=0.16.12
+pkgrel=1
+pkgdesc="A lightweight C library for storing RDF data in memory"
+arch=(x86_64)
+url="https://drobilla.net/software/sord.html"
+license=(custom:ISC)
+makedepends=(doxygen glibc meson pcre python-sphinx serd)
+provides=(libsord-0.so)
+options=(debug)
+source=(https://download.drobilla.net/$pkgname-$pkgver.tar.xz{,.sig})
+sha512sums=('d63cc1473d12676dac3724a096c85fd47745e456cf4b191fd9f8aaf8bb9399510c6878948fd045cc1942356e61dbefd8d88374c1ef6b327057e0bb8bfa03f926'
+            'SKIP')
+b2sums=('9b89848440a994145a934e66e6fe7b844e82e926cb48d05223faef9357d315db981cd68b1174d7c47e5d63b97f8e15d8cc6b2b992a6bd790b8b117ebbb6c059a'
+        'SKIP')
+validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d at drobilla.net>
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+build() {
+  arch-meson $pkgname-$pkgver build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package_sord() {
+  depends=(glibc libserd-0.so pcre)
+
+  meson install -C build --destdir "$pkgdir"
+  (
+    cd "$pkgdir"
+    _pick $pkgname-docs usr/share/doc
+  )
+  install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 $pkgname-$pkgver/{AUTHORS,NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"
+}
+
+package_sord-docs() {
+  pkgdesc+=" - documentation"
+
+  mv -v $pkgname/* "$pkgdir"
+  mv -v "$pkgdir/usr/share/doc/"sord{-0,}
+}