[arch-commits] Commit in element/repos/community-x86_64 (PKGBUILD PKGBUILD keys)

[David Runge]

    Date: Wednesday, July 20, 2022 @ 12:19:02
  Author: dvzrv
Revision: 1254883

archrelease: copy trunk to community-x86_64

Added:
  element/repos/community-x86_64/PKGBUILD
    (from rev 1254882, element/trunk/PKGBUILD)
  element/repos/community-x86_64/keys/
Deleted:
  element/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  150 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 80 insertions(+), 70 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-07-20 12:18:05 UTC (rev 1254882)
+++ PKGBUILD	2022-07-20 12:19:02 UTC (rev 1254883)
@@ -1,70 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-
-pkgname=element
-pkgver=0.46.5
-pkgrel=1
-pkgdesc="A modular LV2/VST3 audio plugin host"
-arch=(x86_64)
-url="https://github.com/kushview/element"
-license=(GPL3)
-groups=(pro-audio)
-depends=(gcc-libs glibc hicolor-icon-theme libx11 libxext)
-makedepends=(alsa-lib boost curl freetype2 git gtk3 imagemagick jack juce
-ladspa ldoc libxcomposite libxcursor libxinerama lilv lua lv2 pango readline
-serd sord sratom suil waf xorg-xrandr)
-checkdepends=(xorg-server-xvfb)
-optdepends=('lua: for LUA scripting')
-provides=(ladspa-host lv2-host vst3-host)
-options=(debug)
-source=(
-  git+https://github.com/kushview/$pkgname#tag=$pkgver?signed
-  git+https://github.com/kushview/kv-modules
-  git+https://github.com/kushview/JUCE.git
-  git+https://github.com/lvtk/jlv2
-)
-sha512sums=('SKIP'
-            'SKIP'
-            'SKIP'
-            'SKIP')
-b2sums=('SKIP'
-        'SKIP'
-        'SKIP'
-        'SKIP')
-validpgpkeys=('52CB000FABB9DBE345CD478980A5F4BE60360CDE') # Michael Fisher <mfisher at kushview.net>
-
-prepare() {
-  cd $pkgname
-  git submodule init
-  git config submodule.libs/kv.url "$srcdir/kv-modules"
-  git config submodule.libs/JUCE.url "$srcdir/JUCE"
-  git config submodule.libs/jlv2.url "$srcdir/jlv2"
-  git submodule update
-
-  rm -frv waflib
-}
-
-build() {
-  cd $pkgname
-  export LINKFLAGS="$LDFLAGS"
-  waf configure --prefix=/usr \
-                --enable-docking \
-                --test
-  waf build -vv
-}
-
-check() {
-  cd $pkgname
-  LD_LIBRARY_PATH="$PWD/build/lib:$LD_LIBRARY_PATH" xvfb-run waf check \
-  || echo "Known issues with LUA related tests: https://github.com/kushview/Element/issues/439"
-}
-
-package() {
-  depends+=(libasound.so libcurl.so libfreetype.so libjack.so liblilv-0.so
-  libsuil-0.so)
-
-  cd $pkgname
-  waf install --destdir="$pkgdir"
-  install -vDm 644 {AUTHORS,CODE_OF_CONDUCT,CONTRIBUTING,README}.md -t "$pkgdir/usr/share/doc/$pkgname/"
-  install -vDm 644 docs/*.md -t "$pkgdir/usr/share/doc/$pkgname/docs"
-  install -vDm 644 docs/img/*.png -t "$pkgdir/usr/share/doc/$pkgname/docs/img"
-}

Copied: element/repos/community-x86_64/PKGBUILD (from rev 1254882, element/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-07-20 12:19:02 UTC (rev 1254883)
@@ -0,0 +1,80 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=element
+_commit=70135d89febc8bd3a46ad874b8338350ec5e9c49  # refs/tags/0.46.6
+pkgver=0.46.6
+pkgrel=1
+pkgdesc="A modular LV2/VST3 audio plugin host"
+arch=(x86_64)
+url="https://github.com/kushview/element"
+license=(GPL3)
+groups=(pro-audio)
+depends=(gcc-libs glibc hicolor-icon-theme libx11 libxext)
+makedepends=(alsa-lib boost curl freetype2 git gtk3 imagemagick jack juce
+ladspa ldoc libxcomposite libxcursor libxinerama lilv lua lv2 pango readline
+serd sord sratom suil waf xorg-xrandr)
+checkdepends=(xorg-server-xvfb)
+optdepends=('lua: for LUA scripting')
+provides=(ladspa-host lv2-host vst3-host)
+options=(debug)
+source=(
+  git+https://github.com/kushview/$pkgname#tag=$_commit?signed
+  git+https://github.com/kushview/kv-modules
+  git+https://github.com/kushview/JUCE
+  git+https://github.com/lvtk/jlv2
+  git+https://github.com/kushview/lua-kv
+)
+sha512sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP')
+b2sums=('SKIP'
+        'SKIP'
+        'SKIP'
+        'SKIP'
+        'SKIP')
+validpgpkeys=('52CB000FABB9DBE345CD478980A5F4BE60360CDE') # Michael Fisher <mfisher at kushview.net>
+
+prepare() {
+  cd $pkgname
+  git submodule init
+  git submodule deinit "libs/JUCE"
+  git config submodule.libs/kv.url "$srcdir/kv-modules"
+  git config submodule.libs/JUCE.url "$srcdir/JUCE"
+  git config submodule.libs/jlv2.url "$srcdir/jlv2"
+  git config submodule.libs/lua-kv.url "$srcdir/lua-kv"
+  git submodule update
+
+  rm -frv waflib
+}
+
+build() {
+  export LINKFLAGS="$LDFLAGS"
+  CFLAGS+=" -I/usr/share/juce/modules/"
+
+  cd $pkgname
+  waf configure \
+    --prefix=/usr \
+    --enable-docking \
+    --juce-path "/usr/share/juce/modules/" \
+    --test
+  waf build -vv
+}
+
+check() {
+  cd $pkgname
+  LD_LIBRARY_PATH="$PWD/build/lib:$LD_LIBRARY_PATH" xvfb-run waf check \
+  || echo "Known issues with LUA related tests: https://github.com/kushview/Element/issues/439"
+}
+
+package() {
+  depends+=(libasound.so libcurl.so libfreetype.so libjack.so liblilv-0.so
+  libsuil-0.so)
+
+  cd $pkgname
+  waf install --destdir="$pkgdir"
+  install -vDm 644 {AUTHORS,CODE_OF_CONDUCT,CONTRIBUTING,README}.md -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 docs/*.md -t "$pkgdir/usr/share/doc/$pkgname/docs"
+  install -vDm 644 docs/img/*.png -t "$pkgdir/usr/share/doc/$pkgname/docs/img"
+}