[arch-commits] Commit in qtcreator/repos/extra-x86_64 (PKGBUILD PKGBUILD)

Antonio Rojas arojas at gemini.archlinux.org
Wed Jul 20 17:14:50 UTC 2022


    Date: Wednesday, July 20, 2022 @ 17:14:50
  Author: arojas
Revision: 451506

archrelease: copy trunk to extra-x86_64

Added:
  qtcreator/repos/extra-x86_64/PKGBUILD
    (from rev 451505, qtcreator/trunk/PKGBUILD)
Deleted:
  qtcreator/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  131 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 63 insertions(+), 68 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-07-20 17:14:30 UTC (rev 451505)
+++ PKGBUILD	2022-07-20 17:14:50 UTC (rev 451506)
@@ -1,68 +0,0 @@
-# Maintainer: Antonio Rojas <arojas at archlinux.org>
-# Contributor: Sven-Hendrik Haase <sh at lutzhaase.com>
-# Contributor: Imanol Celaya <ornitorrincos at archlinux-es.org>
-# Contributor: Lukas Jirkovsky <l.jirkovsky at gmail.com>
-# Contributor: Dan Vratil <progdan at progdansoft.com>
-# Contributor: thotypous <matiasΘarchlinux-br·org>
-# Contributor: delor <bartekpiech gmail com>
-
-pkgbase=qtcreator
-pkgname=(qtcreator qtcreator-devel)
-pkgver=7.0.2
-_clangver=14.0.6
-pkgrel=4
-pkgdesc='Lightweight, cross-platform integrated development environment'
-arch=(x86_64)
-url='https://www.qt.io'
-license=(GPL3)
-depends=(qt6-tools qt6-svg qt6-quick3d qt6-webengine qt6-serialport qt6-shadertools qt6-5compat
-         clang=$_clangver clazy yaml-cpp litehtml) # syntax-highlighting
-makedepends=(cmake llvm python)
-optdepends=('qt6-doc: integrated Qt documentation'
-            'qt6-examples: welcome page examples'
-            'gdb: debugger'
-            'cmake: cmake project support'
-            'x11-ssh-askpass: ssh support'
-            'git: git support'
-            'mercurial: mercurial support'
-            'bzr: bazaar support'
-            'valgrind: analyze support'
-            'perf: performer analyzer'
-            'mlocate: locator filter')
-source=(https://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz
-        QTCREATORBUG-27096.patch::https://code.qt.io/cgit/qt-creator/qt-creator.git/patch/?id=449334e4)
-sha256sums=('14dee285aa3aa56fb25ccbd7587382fb6cb05ae99a1a30237f0a0bbef3ceff7a'
-            '31d970420ddb32b2c51355a2a3929bb48021c8c5c25614fffaeafe19ad8a61f6')
-options=(docs debug)
-
-prepare() {
-  patch -d qt-creator-opensource-src-$pkgver -p1 < QTCREATORBUG-27096.patch # Fix crash if language client crashes
-}
-
-build() {
-  cmake -B build -S qt-creator-opensource-src-$pkgver \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_INSTALL_LIBEXECDIR=lib \
-    -DWITH_DOCS=ON \
-    -DBUILD_DEVELOPER_DOCS=ON \
-    -DBUILD_QBS=OFF \
-    -DQTC_CLANG_BUILDMODE_MATCH=ON
-  cmake --build build
-  cmake --build build --target docs
-}
-
-package_qtcreator() {
-  DESTDIR="$pkgdir" cmake --install build
-# Install docs
-  cp -r build/share/doc "$pkgdir"/usr/share
-
-  install -Dm644 qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
-}
-
-package_qtcreator-devel() {
-  pkgdesc+=' (development files)'
-  depends=(qtcreator)
-  optdepends=()
-
-  DESTDIR="$pkgdir" cmake --install build --component Devel
-}

Copied: qtcreator/repos/extra-x86_64/PKGBUILD (from rev 451505, qtcreator/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-07-20 17:14:50 UTC (rev 451506)
@@ -0,0 +1,63 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Imanol Celaya <ornitorrincos at archlinux-es.org>
+# Contributor: Lukas Jirkovsky <l.jirkovsky at gmail.com>
+# Contributor: Dan Vratil <progdan at progdansoft.com>
+# Contributor: thotypous <matiasΘarchlinux-br·org>
+# Contributor: delor <bartekpiech gmail com>
+
+pkgbase=qtcreator
+pkgname=(qtcreator qtcreator-devel)
+pkgver=8.0.0
+_clangver=14.0.6
+pkgrel=1
+pkgdesc='Lightweight, cross-platform integrated development environment'
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3)
+depends=(qt6-tools qt6-svg qt6-quick3d qt6-webengine qt6-serialport qt6-shadertools qt6-5compat
+         clang=$_clangver clazy yaml-cpp litehtml) # syntax-highlighting
+makedepends=(cmake llvm python)
+optdepends=('qt6-doc: integrated Qt documentation'
+            'qt6-examples: welcome page examples'
+            'gdb: debugger'
+            'cmake: cmake project support'
+            'x11-ssh-askpass: ssh support'
+            'git: git support'
+            'mercurial: mercurial support'
+            'bzr: bazaar support'
+            'valgrind: analyze support'
+            'perf: performer analyzer'
+            'mlocate: locator filter')
+source=(https://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz)
+sha256sums=('323640f96c76d199fe5bf7b02cbf2dd1a3b6489ab7cc0adeaad3957d8dc96f17')
+options=(docs debug)
+
+build() {
+  cmake -B build -S qt-creator-opensource-src-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DWITH_DOCS=ON \
+    -DBUILD_DEVELOPER_DOCS=ON \
+    -DBUILD_QBS=OFF \
+    -DQTC_CLANG_BUILDMODE_MATCH=ON \
+    -DCLANGTOOLING_LINK_CLANG_DYLIB=ON
+  cmake --build build
+  cmake --build build --target docs
+}
+
+package_qtcreator() {
+  DESTDIR="$pkgdir" cmake --install build
+# Install docs
+  cp -r build/share/doc "$pkgdir"/usr/share
+
+  install -Dm644 qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
+}
+
+package_qtcreator-devel() {
+  pkgdesc+=' (development files)'
+  depends=(qtcreator)
+  optdepends=()
+
+  DESTDIR="$pkgdir" cmake --install build --component Devel
+}



More information about the arch-commits mailing list