[arch-commits] Commit in python-structlog/repos (3 files)

[Chih-Hsuan Yen]

    Date: Friday, July 22, 2022 @ 06:53:17
  Author: yan12125
Revision: 1255180

archrelease: copy trunk to community-testing-any

Added:
  python-structlog/repos/community-testing-any/
  python-structlog/repos/community-testing-any/PKGBUILD
    (from rev 1255179, python-structlog/trunk/PKGBUILD)
  python-structlog/repos/community-testing-any/keys/

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: python-structlog/repos/community-testing-any/PKGBUILD (from rev 1255179, python-structlog/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2022-07-22 06:53:17 UTC (rev 1255180)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+
+pkgname=python-structlog
+# https://www.structlog.org/en/stable/changelog.html
+pkgver=22.1.0
+# curl https://api.github.com/repos/hynek/structlog/git/ref/tags/$pkgver | jq -r .object.sha
+_tag=2b4731d58cdb51350938505fc5f588ec9cf41cb1
+pkgrel=1
+pkgdesc="Structured Logging for Python"
+url="https://www.structlog.org"
+license=('Apache')
+arch=('any')
+depends=('python')
+makedepends=('git' 'python-build' 'python-flit-core' 'python-installer')
+checkdepends=('python-pytest' 'python-freezegun' 'python-pretend' 'python-simplejson'
+              'python-twisted' 'python-rapidjson' 'python-greenlet' 'python-pytest-asyncio'
+              'python-rich')
+optdepends=(
+  'python-greenlet: for greenlet support in structlog.threadlocal (deprecated)'
+  'python-twisted: for structlog.twisted'
+  'python-rich: for structlog.dev'
+)
+# The PyPI tarball is signed, but missing conftest.py
+source=("git+https://github.com/hynek/structlog.git?signed#tag=$_tag")
+sha512sums=('SKIP')
+validpgpkeys=(
+  'C2A04F86ACE28ADCF817DBB7AE2536227F69F181'  # https://github.com/hynek.gpg
+)
+
+pkgver() {
+  cd structlog
+  git describe --tags
+}
+
+build() {
+  cd structlog
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd structlog
+  PYTHONPATH="$PWD"/src pytest
+}
+
+package() {
+  cd structlog
+  python -m installer --destdir="$pkgdir" dist/*.whl
+}