[arch-commits] Commit in appstream-glib/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Saturday, July 23, 2022 @ 19:44:16
  Author: heftig
Revision: 451607

archrelease: copy trunk to testing-x86_64

Added:
  appstream-glib/repos/testing-x86_64/
  appstream-glib/repos/testing-x86_64/PKGBUILD
    (from rev 451606, appstream-glib/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: appstream-glib/repos/testing-x86_64/PKGBUILD (from rev 451606, appstream-glib/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-07-23 19:44:16 UTC (rev 451607)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=appstream-glib
+pkgver=0.8.0
+pkgrel=1
+pkgdesc="Objects and methods for reading and writing AppStream metadata"
+url="https://people.freedesktop.org/~hughsient/appstream-glib/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gtk3 libyaml pacman gcab curl libstemmer)
+makedepends=(gobject-introspection gtk-doc git gperf meson)
+provides=(appdata-tools libappstream-glib.so)
+conflicts=(appdata-tools)
+replaces=(appdata-tools)
+options=(debug)
+_commit=fc9f22621846b0411173be176f06ea7c7a60b172  # tags/appstream_glib_0_8_0^0
+source=("git+https://github.com/hughsie/appstream-glib#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^appstream_glib_//;s/_/./g;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # https://github.com/hughsie/appstream-glib/issues/445
+  git cherry-pick -n 3870226a3585 8d3964003275 674490bd54ff
+}
+
+build() {
+  local meson_options=(
+    -D alpm=true
+    -D gtk-doc=true
+    -D rpm=false
+  )
+
+  arch-meson $pkgname build "${meson_options[@]}"
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim:set sw=2 sts=-1 et: