[arch-commits] Commit in haskell-regex-tdfa/repos (2 files)

[Felix Yan]

    Date: Monday, July 25, 2022 @ 06:13:27
  Author: felixonmars
Revision: 1256695

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-regex-tdfa/repos/community-staging-x86_64/
  haskell-regex-tdfa/repos/community-staging-x86_64/PKGBUILD
    (from rev 1256694, haskell-regex-tdfa/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-regex-tdfa/repos/community-staging-x86_64/PKGBUILD (from rev 1256694, haskell-regex-tdfa/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-07-25 06:13:27 UTC (rev 1256695)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=regex-tdfa
+pkgname=haskell-regex-tdfa
+pkgver=1.3.1.3
+pkgrel=2
+pkgdesc="Pure Haskell Tagged DFA Backend for Text.Regex (regex-base)"
+url="https://wiki.haskell.org/Regular_expressions"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-regex-base')
+makedepends=('ghc' 'uusi' 'haskell-utf8-string')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7eb10d5e1b4edd199385551c37c9a846caaea95c44fc184b20e81a9ab66a86cb24e07de97200550f78b412fbe082a5c566505abff6ccabbc650fc60c18bf6db8')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}