[arch-commits] Commit in jami-daemon/repos (2 files)

[Bruno Pagani]

    Date: Thursday, July 28, 2022 @ 10:47:27
  Author: archange
Revision: 1258975

archrelease: copy trunk to community-testing-x86_64

Added:
  jami-daemon/repos/community-testing-x86_64/
  jami-daemon/repos/community-testing-x86_64/PKGBUILD
    (from rev 1258974, jami-daemon/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: jami-daemon/repos/community-testing-x86_64/PKGBUILD (from rev 1258974, jami-daemon/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-07-28 10:47:27 UTC (rev 1258975)
@@ -0,0 +1,59 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+
+pkgname=jami-daemon
+pkgver=20220722
+pkgrel=1
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (daemon component)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(glibc opendht gnutls nettle libgit2 libsecp256k1 ffmpeg speexdsp
+         fmt yaml-cpp jsoncpp zlib alsa-lib libpulse jack libupnp libnatpmp
+         openssl webrtc-audio-processing systemd-libs libarchive)
+# portaudio needs a not-yet-upstream patch https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/650
+makedepends=(git cmake perl asio msgpack-c msgpack-cxx restinio systemd meson)
+checkdepends=(cppunit)
+_commit=6f64b069a1c95a15b744d4044ad3d8032147439f
+_pjprojectver=4af5d666d18837abaac94c8ec6bfc84984dcf1e2
+source=(git+https://git.jami.net/savoirfairelinux/${pkgname}.git#commit=${_commit}
+        https://github.com/savoirfairelinux/pjproject/archive/${_pjprojectver}/pjproject-${_pjprojectver}.tar.gz)
+noextract=(pjproject-${_pjprojectver}.tar.gz)
+sha512sums=(SKIP 3113daca372c84beda1f9f9a1b73f02ba7d565bb1d40662cc30bf741ec0ffda4e7d69034521073ce12f80498c071166a67959531e39abb865ea8d1e48564677f)
+
+pkgver() {
+  cd ${pkgname}
+  TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD
+}
+
+prepare() {
+  cd ${pkgname}
+  cp ../pjproject-${_pjprojectver}.tar.gz contrib/tarballs
+  mkdir contrib/native
+}
+
+build() {
+  cd ${pkgname}/contrib/native
+  export CXXFLAGS+=' -fpermissive'
+  ../bootstrap \
+      --disable-downloads \
+      --disable-all \
+      --enable-pjproject
+  make DEPS_pjproject=
+
+  cd "${srcdir}"
+  arch-meson ${pkgname} build -D interfaces=library -D opensl=disabled -D portaudio=disabled \
+                              $( ((CHECKFUNC)) && echo -D tests=true) \
+                              -D pkg_config_path="${PWD}/${pkgname}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+  meson compile -C build
+}
+
+#check() {
+# https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/649
+#  meson test -C build --print-errorlogs
+#}
+
+package() {
+  meson install -C build --destdir "${pkgdir}"
+}