[arch-commits] Commit in hledger/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Thu Jun 2 05:31:52 UTC 2022


    Date: Thursday, June 2, 2022 @ 05:31:51
  Author: felixonmars
Revision: 1218561

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger/repos/community-staging-x86_64/
  hledger/repos/community-staging-x86_64/PKGBUILD
    (from rev 1218560, hledger/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: hledger/repos/community-staging-x86_64/PKGBUILD (from rev 1218560, hledger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-02 05:31:51 UTC (rev 1218561)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger
+pkgver=1.25
+pkgrel=45
+pkgdesc="Command-line interface for the hledger accounting system"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-cmdargs'
+         'haskell-data-default' 'haskell-decimal' 'haskell-diff' 'haskell-githash'
+         'haskell-hashable' 'haskell-hledger-lib' 'haskell-lucid' 'haskell-math-functions'
+         'haskell-megaparsec' 'haskell-microlens' 'haskell-regex-tdfa' 'haskell-safe'
+         'haskell-shakespeare' 'haskell-split' 'haskell-tabular' 'haskell-tasty'
+         'haskell-temporary' 'haskell-unordered-containers' 'haskell-utf8-string'
+         'haskell-utility-ht' 'haskell-wizards')
+makedepends=('ghc' 'haskell-extra' 'haskell-timeit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('3a82fe62cb24b4f0a6216a020153a59d43927cb2ae9e6a92c2c8ac7a69192d63c9c521e94adfe7c3505a23555b0e78a458988c34a53f1b5e896e38c41fa611b6')
+
+build() {
+    cd $pkgname-$pkgver
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -fterminfo -fthreaded --ghc-option='-pie'
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $pkgname-$pkgver
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+
+    install -Dm644 hledger.1 -t "$pkgdir"/usr/share/man/man1/
+    install -Dm644 shell-completion/hledger-completion.bash "$pkgdir"/usr/share/bash-completion/completions/hledger
+}



More information about the arch-commits mailing list