[arch-commits] Commit in haskell-turtle/repos (2 files)

[Felix Yan]

    Date: Sunday, June 5, 2022 @ 19:15:24
  Author: felixonmars
Revision: 1224044

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-turtle/repos/community-staging-x86_64/
  haskell-turtle/repos/community-staging-x86_64/PKGBUILD
    (from rev 1224043, haskell-turtle/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-turtle/repos/community-staging-x86_64/PKGBUILD (from rev 1224043, haskell-turtle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-05 19:15:24 UTC (rev 1224044)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=turtle
+pkgname=haskell-turtle
+pkgver=1.5.25
+pkgrel=13
+pkgdesc="Shell programming, Haskell-style"
+url="https://github.com/Gabriel439/Haskell-Turtle-Library"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-wl-pprint' 'haskell-async' 'haskell-clock'
+         'haskell-foldl' 'haskell-hostname' 'haskell-managed' 'haskell-optparse-applicative'
+         'haskell-optional-args' 'haskell-streaming-commons' 'haskell-system-fileio'
+         'haskell-system-filepath' 'haskell-temporary' 'haskell-unix-compat')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('e29fd8ff1e75ef2678d0cbb93e0593481e842481846c2b8dfec2fbf756b945d60b275190f5ac32381ec76c1129179ae8dbe054b838ff8dd3bba7f9d210e0259c')
+
+prepare() {
+    sed -i 's/]/, "-dynamic"]/' $_hkgname-$pkgver/test/Main.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}