[arch-commits] Commit in haskell-statistics/repos (2 files)

[Felix Yan]

    Date: Sunday, June 5, 2022 @ 19:27:53
  Author: felixonmars
Revision: 1224128

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-statistics/repos/community-staging-x86_64/
  haskell-statistics/repos/community-staging-x86_64/PKGBUILD
    (from rev 1224127, haskell-statistics/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-statistics/repos/community-staging-x86_64/PKGBUILD (from rev 1224127, haskell-statistics/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-05 19:27:53 UTC (rev 1224128)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=statistics
+pkgname=haskell-statistics
+pkgver=0.16.0.1
+pkgrel=17
+pkgdesc="A library of statistical types, data, and functions"
+url="https://github.com/haskell/statistics"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-async' 'haskell-data-default-class'
+         'haskell-dense-linear-algebra' 'haskell-math-functions' 'haskell-monad-par'
+         'haskell-mwc-random' 'haskell-primitive' 'haskell-random' 'haskell-vector'
+         'haskell-vector-algorithms' 'haskell-vector-binary-instances' 'haskell-vector-th-unbox')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-erf' 'haskell-ieee754'
+             'haskell-tasty' 'haskell-tasty-expected-failure' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('cead6405b5efbea94dc42fe82f2a85e94ef2841b31a7b8fa6f01d81fed52f5909ce65be3ea28ee2dad91aba360a0229a10431046bbd3ac96664f9d31f61e1bf3')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}