[arch-commits] Commit in haskell-jose/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Mon Jun 6 05:45:17 UTC 2022


    Date: Monday, June 6, 2022 @ 05:45:17
  Author: felixonmars
Revision: 1224373

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-jose/repos/community-staging-x86_64/
  haskell-jose/repos/community-staging-x86_64/PKGBUILD
    (from rev 1224372, haskell-jose/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: haskell-jose/repos/community-staging-x86_64/PKGBUILD (from rev 1224372, haskell-jose/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-06 05:45:17 UTC (rev 1224373)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=jose
+pkgname=haskell-jose
+pkgver=0.8.5
+pkgrel=79
+pkgdesc="Javascript Object Signing and Encryption and JSON Web Token library"
+url="https://github.com/frasertweedale/hs-jose"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base64-bytestring' 'haskell-concise'
+         'haskell-cryptonite' 'haskell-lens' 'haskell-memory' 'haskell-monad-time'
+         'haskell-safe' 'haskell-aeson' 'haskell-unordered-containers' 'haskell-network-uri'
+         'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-x509' 'haskell-vector')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('2a2f58375869963ca0e4c2075392f9124f6ba6eadf9cb4721e83d13107bd71e5344f7e05f84326fec84a9154e7cb7288703a73c536efd8962172e087383a0c83')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list