[arch-commits] Commit in python-cookiecutter/trunk (PKGBUILD)

[David Runge]

    Date: Tuesday, June 7, 2022 @ 12:17:25
  Author: dvzrv
Revision: 1228466

upgpkg: python-cookiecutter 2.1.1-1: Upgrade to 2.1.1.

Remove unnecessary quotes and curly braces.
Switch to PEP517.

Modified:
  python-cookiecutter/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++--------------------------
 1 file changed, 21 insertions(+), 26 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-06-07 12:08:44 UTC (rev 1228465)
+++ PKGBUILD	2022-06-07 12:17:25 UTC (rev 1228466)
@@ -2,44 +2,39 @@
 
 _name=cookiecutter
 pkgname=python-cookiecutter
-pkgver=1.7.3
-pkgrel=3
+pkgver=2.1.1
+pkgrel=1
 pkgdesc="A command-line utility that creates projects from project templates"
-arch=('any')
+arch=(any)
 url="https://github.com/cookiecutter/cookiecutter"
-license=('BSD')
-depends=('python-binaryornot' 'python-click' 'python-jinja' 'python-jinja-time'
-'python-poyo' 'python-requests' 'python-six' 'python-slugify')
-makedepends=('python-setuptools')
-checkdepends=('git' 'python-freezegun' 'python-pytest' 'python-pytest-mock')
-source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
-sha512sums=('231cff1fc51c8159918728a3ca3f21607c9fb236ebf55e2fe2d620345e14451b175e56c3714a7b4c5736cc5e93f47d732691e789184e4140a7889a9e2f9a89a8')
-b2sums=('3f0630d99e784250cf39c3f9c2e28907abc2c208aefffcc52ef78f987591ee76712d858288736bd4553393385a31ceaa509ac566630fb509fa11a088da01693e')
+license=(BSD)
+depends=(python-binaryornot python-click python-jinja python-jinja-time
+python-pyyaml python-requests python-slugify)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(git python-freezegun python-pytest python-pytest-mock)
+source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
+sha512sums=('5e249dab7a71a4213f81b887912d9aae3747b16fce8ede2fb7c7efbd2802871d512540ddc676b9419bafe3b73f0aa5ad6b0b15b16d429f7081e101ad53564193')
+b2sums=('17d63625b8822ea3f9b592f5b9ab9ba9b782d3b312ac4aee614e23cba16e4e182b5b2d08197da24c678d25590158a1f8d29c528d2e9437b10bcaabc08ad8dd4d')
 
 prepare() {
-  mv -v "${_name}-${pkgver}" "$pkgname-$pkgver"
-  cd "$pkgname-$pkgver"
   # we do not care about code coverage in pytest runs
-  sed -e '/addopts/d' -i setup.cfg
+  sed -e '/addopts/d' -i $_name-$pkgver/setup.cfg
 }
 
 build() {
-  cd "$pkgname-$pkgver"
-  python setup.py build
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
 }
 
 check() {
-  cd "$pkgname-$pkgver"
-  export PYTHONPATH="build:${PYTHONPATH}"
-  pytest -v
+  cd $_name-$pkgver
+  export PYTHONPATH="build:$PYTHONPATH"
+  pytest -vv
 }
 
 package() {
-  cd "$pkgname-$pkgver"
-  python setup.py install --skip-build \
-    --optimize=1 \
-    --prefix=/usr \
-    --root="${pkgdir}"
-  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
-  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+  install -vDm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
 }