[arch-commits] Commit in cbindgen/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Tuesday, June 7, 2022 @ 14:40:13
  Author: heftig
Revision: 447723

archrelease: copy trunk to extra-x86_64

Added:
  cbindgen/repos/extra-x86_64/PKGBUILD
    (from rev 447722, cbindgen/trunk/PKGBUILD)
Deleted:
  cbindgen/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   98 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 49 insertions(+), 49 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-06-07 14:39:58 UTC (rev 447722)
+++ PKGBUILD	2022-06-07 14:40:13 UTC (rev 447723)
@@ -1,49 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-
-pkgname=cbindgen
-pkgver=0.23.0
-pkgrel=1
-pkgdesc="A tool for generating C bindings to Rust code"
-url="https://github.com/eqrion/cbindgen"
-arch=(x86_64)
-license=(MPL2)
-depends=(gcc-libs)
-makedepends=(cargo git)
-checkdepends=(cython)
-options=(debug)
-_commit=798cfab52bced65a749443faa16990ec3a8e0cfe  # tags/v0.23.0^0
-source=("git+https://github.com/eqrion/cbindgen#commit=$_commit")
-sha512sums=('SKIP')
-
-# Use LTO
-export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
-
-# Use debug
-export CARGO_PROFILE_RELEASE_DEBUG=2
-
-pkgver() {
-  cd cbindgen
-  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
-}
-
-prepare() {
-  cd cbindgen
-  cargo fetch --locked --target x86_64-unknown-linux-gnu
-}
-
-build() {
-  cd cbindgen
-  cargo build --release --frozen --all-targets
-}
-
-check() {
-  cd cbindgen
-  # Tests need nightly features
-  RUSTC_BOOTSTRAP=1 cargo test --release --frozen
-}
-
-package() {
-  cd cbindgen
-  install -Dt "$pkgdir/usr/bin" target/release/cbindgen
-  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 README.md
-}

Copied: cbindgen/repos/extra-x86_64/PKGBUILD (from rev 447722, cbindgen/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-06-07 14:40:13 UTC (rev 447723)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=cbindgen
+pkgver=0.24.0
+pkgrel=1
+pkgdesc="A tool for generating C bindings to Rust code"
+url="https://github.com/eqrion/cbindgen"
+arch=(x86_64)
+license=(MPL2)
+depends=(gcc-libs)
+makedepends=(cargo git)
+checkdepends=(cython)
+options=(debug)
+_commit=f0d4f284f7a2d3b84c8b7bfca422a0eec4605b71  # tags/v0.24.0^0
+source=("git+$url#commit=$_commit")
+sha512sums=('SKIP')
+
+# Use LTO
+export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
+
+# Use debug
+export CARGO_PROFILE_RELEASE_DEBUG=2
+
+pkgver() {
+  cd cbindgen
+  git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd cbindgen
+  cargo fetch --locked --target x86_64-unknown-linux-gnu
+}
+
+build() {
+  cd cbindgen
+  cargo build --release --frozen --all-targets
+}
+
+check() {
+  cd cbindgen
+  # Tests need nightly features
+  RUSTC_BOOTSTRAP=1 cargo test --release --frozen
+}
+
+package() {
+  cd cbindgen
+  install -Dt "$pkgdir/usr/bin" target/release/cbindgen
+  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 README.md
+}