[arch-commits] Commit in haskell-language-server/repos (2 files)

[Felix Yan]

    Date: Wednesday, June 8, 2022 @ 05:40:25
  Author: felixonmars
Revision: 1228723

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-language-server/repos/community-staging-x86_64/
  haskell-language-server/repos/community-staging-x86_64/PKGBUILD
    (from rev 1228722, haskell-language-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: haskell-language-server/repos/community-staging-x86_64/PKGBUILD (from rev 1228722, haskell-language-server/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-08 05:40:25 UTC (rev 1228723)
@@ -0,0 +1,67 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=haskell-language-server
+pkgver=1.3.0.0
+pkgrel=202
+pkgdesc="LSP server for GHC"
+url="https://github.com/haskell/haskell-language-server#readme"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-async'
+         'haskell-base16-bytestring' 'haskell-cryptohash-sha1' 'haskell-data-default'
+         'haskell-extra' 'haskell-ghc' 'haskell-ghc-api-compat' 'haskell-ghc-paths' 'haskell-gitrev'
+         'haskell-hashable' 'haskell-hie-bios' 'haskell-hiedb'
+         'haskell-hls-call-hierarchy-plugin' 'haskell-hls-eval-plugin'
+         'haskell-hls-explicit-imports-plugin' 'haskell-hls-floskell-plugin'
+         'haskell-hls-fourmolu-plugin' 'haskell-hls-ormolu-plugin' 'haskell-hls-graph'
+         'haskell-hls-haddock-comments-plugin' 'haskell-hls-hlint-plugin'
+         'haskell-hls-module-name-plugin' 'haskell-hls-ormolu-plugin' 'haskell-hls-plugin-api'
+         'haskell-hls-pragmas-plugin'
+         'haskell-hls-retrie-plugin' 'haskell-hls-stylish-haskell-plugin'
+         'haskell-hslogger' 'haskell-lens' 'haskell-lsp' 'haskell-optparse-applicative'
+         'haskell-optparse-simple' 'haskell-regex-tdfa' 'haskell-safe-exceptions'
+         'haskell-sqlite-simple' 'haskell-temporary' 'haskell-unordered-containers')
+# Disabled due to not compatible with GHC 9:
+# 'haskell-hls-brittany-plugin' 'haskell-hls-class-plugin' 'haskell-hls-splice-plugin' 'haskell-hls-tactics-plugin' 'haskell-hls-refine-imports-plugin'
+makedepends=('ghc' 'uusi' 'haskell-hls-test-utils' 'haskell-hspec-expectations' 'haskell-lsp-test'
+             'haskell-lsp-types')
+checkdepends=('cabal-install')
+source=("https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz")
+sha512sums=('2938c4eaf8e2fef72ddf0e116e021b109ab69c4cdd48dc678cb93cd08e03e7f2abf3aaf1dea17a51dd8cb70f69db7ceba9823291d847ffe8bd0c990028fd6da4')
+
+prepare() {
+  cd $pkgname-$pkgver
+  find test/testdata -name \*.cabal -exec uusi --add-options-all=-dynamic {} \;
+  uusi -u ghc-api-compat $pkgname.cabal
+}
+
+build() {
+  cd $pkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' -f-brittany -f-class -f-refineImports -f-tactic -f-splice
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $pkgname-$pkgver
+  PATH="$PWD/dist/build/haskell-language-server:$PWD/dist/build/haskell-language-server-wrapper:$PATH" LD_LIBRARY_PATH="$PWD/dist/build" runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}