[arch-commits] Commit in sqlitebrowser/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Levente Polyak]

    Date: Thursday, June 9, 2022 @ 15:05:19
  Author: anthraxx
Revision: 1229684

archrelease: copy trunk to community-x86_64

Added:
  sqlitebrowser/repos/community-x86_64/PKGBUILD
    (from rev 1229683, sqlitebrowser/trunk/PKGBUILD)
Deleted:
  sqlitebrowser/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  112 +++++++++++++++++++++++++++++++++++--------------------------
 1 file changed, 66 insertions(+), 46 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-06-09 15:05:15 UTC (rev 1229683)
+++ PKGBUILD	2022-06-09 15:05:19 UTC (rev 1229684)
@@ -1,46 +0,0 @@
-# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
-# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
-# Contributor: Douglas Soares de Andrade <dsandrade at gmail.com>
-# Contributor: Michael Fellinger <m.fellinger at gmail.com>
-
-pkgname=sqlitebrowser
-_gitcommit=v3.12.2
-pkgver=3.12.2
-pkgrel=1
-pkgdesc='SQLite Database browser is a light GUI editor for SQLite databases, built on top of Qt'
-url='https://sqlitebrowser.org/'
-arch=('x86_64')
-license=('GPL3')
-depends=('qt5-base' 'hicolor-icon-theme' 'desktop-file-utils')
-makedepends=('git' 'cmake' 'ninja' 'qt5-tools')
-source=("git+https://github.com/sqlitebrowser/sqlitebrowser#tag=${_gitcommit}?signed")
-sha256sums=('SKIP')
-validpgpkeys=('05E463FDB5802C3D00257F9C79EAD0AB3BD7DD2C') # Justin Clift (GPG key for signing git commits) <justin at postgresql.org>
-
-pkgver() {
-  cd ${pkgname}
-  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
-}
-
-build() {
-  cd ${pkgname}
-  cmake -B build \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_BUILD_TYPE=None \
-    -DENABLE_TESTING=ON \
-    -Wno-dev \
-    -G Ninja
-  ninja -C build
-}
-
-check() {
-  cd ${pkgname}/build
-  ctest -V
-}
-
-package() {
-  cd ${pkgname}
-  DESTDIR="${pkgdir}" ninja -C build install
-}
-
-# vim: ts=2 sw=2 et:

Copied: sqlitebrowser/repos/community-x86_64/PKGBUILD (from rev 1229683, sqlitebrowser/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-06-09 15:05:19 UTC (rev 1229684)
@@ -0,0 +1,66 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Douglas Soares de Andrade <dsandrade at gmail.com>
+# Contributor: Michael Fellinger <m.fellinger at gmail.com>
+# Contributor: Steffen Jaeckel <arch-pkgs at jaeckel.eu>
+
+pkgname=sqlitebrowser
+_gitcommit=v3.12.2
+pkgver=3.12.2
+pkgrel=2
+pkgdesc='SQLite Database browser is a light GUI editor for SQLite databases, built on top of Qt'
+url='https://sqlitebrowser.org/'
+arch=(x86_64)
+license=(GPL3)
+depends=(
+  qt5-base hicolor-icon-theme sqlcipher qcustomplot qhexedit2 qscintilla-qt5
+  libqcustomplot.so libqhexedit.so
+)
+makedepends=(git cmake ninja qt5-tools)
+options=(debug)
+source=("git+https://github.com/sqlitebrowser/sqlitebrowser#tag=${_gitcommit}?signed")
+sha256sums=('SKIP')
+validpgpkeys=(
+  '05E463FDB5802C3D00257F9C79EAD0AB3BD7DD2C' # Justin Clift (GPG key for signing git commits) <justin at postgresql.org>
+)
+
+pkgver() {
+  cd ${pkgname}
+  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd ${pkgname}
+  rm -r libs/{qcustomplot-source,qhexedit,qscintilla}
+  # fix qhexedit2 detection
+  git cherry-pick --no-commit 4e7669bd0c6d9ca2c57b597f7d67df0e96bd12de
+  git cherry-pick --no-commit 93b16bdad08e685d3b6fc1981dc50e92cfd4d0c3
+}
+
+build() {
+  cd ${pkgname}
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DBUILD_STABLE_VERSION=ON \
+    -DENABLE_TESTING=ON \
+    -DFORCE_INTERNAL_QCUSTOMPLOT=OFF \
+    -DFORCE_INTERNAL_QSCINTILLA=OFF \
+    -DFORCE_INTERNAL_QHEXEDIT=OFF \
+    -Dsqlcipher=1 \
+    -Wno-dev \
+    -G Ninja
+  ninja -C build
+}
+
+check() {
+  cd ${pkgname}/build
+  ctest -V
+}
+
+package() {
+  cd ${pkgname}
+  DESTDIR="${pkgdir}" ninja -C build install
+}
+
+# vim: ts=2 sw=2 et: