[arch-commits] Commit in nginx-mod-cache_purge/repos (2 files)

[Giancarlo Razzolini]

    Date: Friday, June 10, 2022 @ 12:48:48
  Author: grazzolini
Revision: 1230045

archrelease: copy trunk to community-staging-x86_64

Added:
  nginx-mod-cache_purge/repos/community-staging-x86_64/
  nginx-mod-cache_purge/repos/community-staging-x86_64/PKGBUILD
    (from rev 1230044, nginx-mod-cache_purge/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: nginx-mod-cache_purge/repos/community-staging-x86_64/PKGBUILD (from rev 1230044, nginx-mod-cache_purge/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-10 12:48:48 UTC (rev 1230045)
@@ -0,0 +1,47 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=nginx-mod-cache_purge
+pkgver=2.5.2
+pkgrel=2
+
+_modname="${pkgname#nginx-mod-}"
+
+pkgdesc='Nginx module with ability to purge content from FastCGI, proxy, SCGI and uWSGI caches'
+arch=('x86_64')
+depends=('nginx')
+makedepends=('nginx-src')
+url="https://github.com/nginx-modules/ngx_cache_purge"
+license=('CUSTOM')
+
+source=(
+	https://github.com/nginx-modules/ngx_cache_purge/archive/$pkgver/ngx_cache_purge-$pkgver.tar.gz
+)
+
+validpgpkeys=(
+	'B0F4253373F8F6F510D42178520A9993A1C052F8' # Maxim Dounin <mdounin at mdounin.ru>
+)
+
+sha256sums=('552ff1b9a8bcf77b21093b0e2e59a86852870ffda8c97af8ca9422ccd90ccd5f')
+
+prepare() {
+	mkdir -p build
+	cd build
+	ln -sf /usr/src/nginx/auto
+	ln -sf /usr/src/nginx/src
+}
+
+build() {
+	cd build
+	/usr/src/nginx/configure --with-compat --add-dynamic-module=../ngx_cache_purge-$pkgver
+	make modules
+}
+
+package() {
+	install -Dm644 "$srcdir"/ngx_cache_purge-$pkgver/LICENSE \
+	               "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+	cd build/objs
+	for mod in *.so; do
+		install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
+	done
+}