[arch-commits] Commit in rosegarden/repos/community-x86_64 (PKGBUILD PKGBUILD)

[David Runge]

    Date: Friday, June 10, 2022 @ 17:02:02
  Author: dvzrv
Revision: 1230769

archrelease: copy trunk to community-x86_64

Added:
  rosegarden/repos/community-x86_64/PKGBUILD
    (from rev 1230768, rosegarden/trunk/PKGBUILD)
Deleted:
  rosegarden/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  118 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 60 insertions(+), 58 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-06-10 17:01:54 UTC (rev 1230768)
+++ PKGBUILD	2022-06-10 17:02:02 UTC (rev 1230769)
@@ -1,58 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-# Contributor: Ray Rashif <schiv at archlinux.org>
-# Contributor: Giovanni Scafora <giovanni at archlinux.org>
-# Contributor: damir <damir at archlinux.org>
-# Contributor: Robert Emil Berge <robert at rebi.no>
-
-pkgname=rosegarden
-pkgver=21.12
-pkgrel=1
-pkgdesc="MIDI/audio sequencer and notation editor"
-arch=(x86_64)
-url="https://www.rosegardenmusic.com/"
-license=(GPL2)
-groups=(pro-audio)
-depends=(gcc-libs glibc lirc hicolor-icon-theme qt5-base zlib)
-makedepends=(alsa-lib cmake dssi fftw jack ladspa liblrdf liblo
-libsamplerate libsndfile qt5-tools)
-checkdepends=(xorg-server-xvfb)
-optdepends=('cups: Printing support'
-            'evince: Print preview support'
-            'lilypond: Notation display support'
-            'mupdf: Print preview support'
-            'okular: Print preview support'
-            'timidity++: Softsynth support'
-            'flac: FLAC support'
-            'wavpack: Lossless audio codec support')
-provides=(dssi-host ladspa-host)
-source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2")
-sha512sums=('d11756f57e4f364993af67e4aa10c25ef6a7f5fd4baddd127df50c84c29d31aa1e4a42485c8503e9fca31a8cf8e50c3c5b3bad2a08ac945a3fc8cd1a5874d4be')
-b2sums=('d1f3bbd173e1d082c5380be2fe0bd9818a741498add5edc9b24c47b9e37e24b928869c00734bf84dd9c2cb9a79fed15275de35a8e7cd4cbbd8ff6cdcb739c09d')
-
-build() {
-  cd "${pkgname}-${pkgver}"
-  cmake -DCMAKE_INSTALL_PREFIX=/usr \
-        -DCMAKE_BUILD_TYPE=None \
-        -Wno-dev \
-        -B build \
-        -S .
-  make VERBOSE=1 -C build
-}
-
-check() {
-  cd "${pkgname}-${pkgver}"
-  mkdir -p test-tmp
-  chmod 700 test-tmp
-  export XDG_RUNTIME_DIR="${PWD}/test-tmp"
-  xvfb-run make VERBOSE=1 test -C build || echo "TestNotationViewSelection still fails: https://sourceforge.net/p/rosegarden/bugs/1585/"
-}
-
-package() {
-  depends+=(libasound.so libfftw3f.so libjack.so liblrdf.so liblo.so
-  libsamplerate.so libsndfile.so)
-
-  cd "${pkgname}-${pkgver}"
-  make DESTDIR="$pkgdir" install -C build
-  install -vDm 644 {AUTHORS,CHANGELOG,README} -t "${pkgdir}/usr/share/doc/${pkgname}"
-}
-# vim:set ts=2 sw=2 et:

Copied: rosegarden/repos/community-x86_64/PKGBUILD (from rev 1230768, rosegarden/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-06-10 17:02:02 UTC (rev 1230769)
@@ -0,0 +1,60 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+# Contributor: Robert Emil Berge <robert at rebi.no>
+
+pkgname=rosegarden
+pkgver=22.06
+pkgrel=1
+pkgdesc="MIDI/audio sequencer and notation editor"
+arch=(x86_64)
+url="https://www.rosegardenmusic.com/"
+license=(GPL2)
+groups=(pro-audio)
+depends=(gcc-libs glibc lirc hicolor-icon-theme qt5-base zlib)
+makedepends=(alsa-lib cmake dssi fftw jack ladspa liblrdf liblo
+libsamplerate libsndfile qt5-tools)
+checkdepends=(lilypond python tex-gyre-fonts ttf-dejavu xorg-server-xvfb)
+optdepends=(
+  'cups: Printing support'
+  'evince: Print preview support'
+  'lilypond: Notation display support'
+  'mupdf: Print preview support'
+  'okular: Print preview support'
+  'timidity++: Softsynth support'
+  'flac: FLAC support'
+  'wavpack: Lossless audio codec support'
+)
+provides=(dssi-host ladspa-host)
+options=(debug)
+source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2)
+sha512sums=('42ce03a65f9c9401cb3f641c0ae80a827e18d6f47420add382f63273f4644eac5997befe70cac972380441a43d74153a4e37a276fc3dc8d9889eb8671759ab5a')
+b2sums=('d4ba13ac6b4cba6d0b5bc555933737d696d380737e56a3e4e1dd782aff641dcbd49af50aade75550b8a0e22a45f491585ffb4166b21cb9889eca1a2e546c585a')
+
+build() {
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=None \
+        -Wno-dev \
+        -B build \
+        -S $pkgname-$pkgver
+  cmake --build build
+}
+
+check() {
+  mkdir -p test-tmp
+  chmod 700 test-tmp
+  export XDG_RUNTIME_DIR="${PWD}/test-tmp"
+  # disable broken lilypond_export_test: https://sourceforge.net/p/rosegarden/bugs/1640/
+  # disable tests incompatible with debug symbols: https://sourceforge.net/p/rosegarden/bugs/1641/
+  xvfb-run ctest --output-on-failure --test-dir build/test -E '^(lilypond_export_test|test_notationview_selection|convert)$'
+}
+
+package() {
+  depends+=(libasound.so libfftw3f.so libjack.so liblrdf.so liblo.so
+  libsamplerate.so libsndfile.so)
+
+  DESTDIR="$pkgdir" cmake --install build
+  install -vDm 644 $pkgname-$pkgver/{AUTHORS,CHANGELOG,README} -t "$pkgdir/usr/share/doc/$pkgname/"
+}
+# vim:set ts=2 sw=2 et: