[arch-commits] Commit in multipath-tools/repos (2 files)

[Christian Hesse]

    Date: Friday, June 10, 2022 @ 20:38:33
  Author: eworm
Revision: 1231361

archrelease: copy trunk to community-testing-x86_64

Added:
  multipath-tools/repos/community-testing-x86_64/
  multipath-tools/repos/community-testing-x86_64/PKGBUILD
    (from rev 1231360, multipath-tools/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: multipath-tools/repos/community-testing-x86_64/PKGBUILD (from rev 1231360, multipath-tools/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-06-10 20:38:33 UTC (rev 1231361)
@@ -0,0 +1,50 @@
+# Maintainer: Robin Broda <robin at broda.me>
+# Contributor: Michael Lass <bevan at bi-co.net>
+# Contributor: Justin Dray <justin at dray.be>
+# Contributor: Patrick McCarty <pnorcks at gmail dot com>
+# Contributor: Bartłomiej Piotrowski <nospam at bpiotrowski.pl>
+# Contributor: Thomas S Hatch <thatch45 ar gmail dot com>
+# Contributor: Michael P <ptchinster at archlinux.us>
+# Contributor: Matt Heagney <matt at heagney.com>
+
+pkgname=multipath-tools
+_tag='686797b7d0da4fc24fdfcb0fc6364df78a0b232d' # git rev-parse ${pkgver}
+pkgver=0.9.0
+pkgrel=1
+pkgdesc='Multipath tools for Linux (including kpartx)'
+arch=('x86_64')
+url='http://christophe.varoqui.free.fr/'
+license=('GPL2')
+depends=('libaio' 'device-mapper' 'json-c' 'liburcu' 'systemd-libs')
+makedepends=('git' 'systemd')
+source=("multipath-tools::git+https://github.com/opensvc/multipath-tools#tag=${_tag}")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "${pkgname}"
+
+  # Fix systemd version detection in Makefile
+  sed -i 's/sed -n .*$/head -n1 | cut -d" " -f2\)/g' Makefile.inc
+
+  # Fix bindir in Makefile
+  sed -i 's|$(exec_prefix)/sbin|$(exec_prefix)/bin|g' Makefile.inc
+}
+
+build() {
+  cd "${pkgname}"
+
+  make \
+    FORTIFY_OPT=""
+}
+
+package() {
+  cd "${pkgname}"
+
+  make -j1 \
+    DESTDIR="${pkgdir}" \
+    exec_prefix="/usr" \
+    LIB="/usr/lib" \
+    install
+
+  install -D -m0644 -t "${pkgdir}/usr/share/doc/${pkgname}" README*
+}