[arch-commits] Commit in (lapce lapce/repos lapce/trunk lapce/trunk/PKGBUILD)

[Caleb Maclennan]

    Date: Saturday, June 11, 2022 @ 12:48:35
  Author: alerque
Revision: 1233405

Migrate lapce from AUR

Added:
  lapce/
  lapce/repos/
  lapce/trunk/
  lapce/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: lapce/trunk/PKGBUILD
===================================================================
--- lapce/trunk/PKGBUILD	                        (rev 0)
+++ lapce/trunk/PKGBUILD	2022-06-11 12:48:35 UTC (rev 1233405)
@@ -0,0 +1,45 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=lapce
+pkgver=0.1.2
+pkgrel=1
+pkgdesc='Lightning-fast and Powerful Code Editor'
+arch=(x86_64)
+url=https://lapce.dev
+_url="https://github.com/$pkgname/$pkgname"
+license=('Apache')
+depends=(expat
+         fontconfig
+         freetype2
+         gcc-libs
+         gtk3
+         libxcb
+         libxkbcommon)
+makedepends=(cargo
+             python
+             cmake)
+options=('!lto')
+_archive="$pkgname-$pkgver"
+source=("$_url/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('041cc835da6ee73425d150b8d95f136e107e9a2aaced30aaacd981700bee8a6e')
+
+prepare() {
+	cd "$_archive"
+	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+	cd "$_archive"
+	cargo build --frozen --profile release-lto
+}
+
+package() {
+	cd "$_archive"
+	find target/release-lto -maxdepth 1 -executable -type f \
+		-exec install -vDm0755 -t "$pkgdir/usr/bin/" {} +
+	local lname=dev.lapce.lapce
+	install -vDm0644 -t "$pkgdir/usr/share/applications/" extra/linux/$lname.desktop
+	install -vDm0644 -t "$pkgdir/usr/share/metainfo/" extra/linux/$lname.metainfo.xml
+	install -vDm0644 extra/images/logo.png "$pkgdir/usr/share/pixmaps/$lname.png"
+}