[arch-commits] Commit in arrow/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Sat Jun 11 15:07:35 UTC 2022
Date: Saturday, June 11, 2022 @ 15:07:35
Author: felixonmars
Revision: 1233843
archrelease: copy trunk to community-staging-x86_64
Added:
arrow/repos/community-staging-x86_64/
arrow/repos/community-staging-x86_64/PKGBUILD
(from rev 1233842, arrow/trunk/PKGBUILD)
----------+
PKGBUILD | 72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 72 insertions(+)
Copied: arrow/repos/community-staging-x86_64/PKGBUILD (from rev 1233842, arrow/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-06-11 15:07:35 UTC (rev 1233843)
@@ -0,0 +1,72 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
+
+pkgname=arrow
+pkgver=8.0.0
+pkgrel=2
+pkgdesc="Columnar in-memory analytics layer for big data."
+arch=(x86_64)
+url="https://arrow.apache.org"
+license=(Apache)
+depends=(apache-orc boost-libs brotli bzip2 double-conversion c-ares gflags
+ grpc google-glog jemalloc libutf8proc lz4 openssl protobuf rapidjson
+ snappy thrift uriparser xsimd zlib zstd)
+provides=(parquet-cpp)
+conflicts=(parquet-cpp)
+makedepends=(boost cmake flatbuffers gmock python-numpy git clang)
+source=(https://archive.apache.org/dist/${pkgname}/${pkgname}-${pkgver}/apache-${pkgname}-${pkgver}.tar.gz{,.asc}
+ git+https://github.com/apache/parquet-testing.git
+ git+https://github.com/apache/arrow-testing.git)
+sha256sums=(ad9a05705117c989c116bae9ac70492fe015050e1b80fb0e38fde4b5d863aaa3 SKIP SKIP SKIP)
+validpgpkeys=(265F80AB84FE03127E14F01125BCCA5220D84079 # Krisztian Szucs (apache) <szucs.krisztian at gmail.com>
+ 08D3564B7C6A9CAFBFF6A66791D18FCF079F8007) # Kouhei Sutou <kou at cozmixng.org>
+
+build(){
+ CC=clang \
+ CXX=clang++ \
+ ARROW_BUILD_TOOLCHAIN=/usr \
+ ORC_HOME=/usr \
+ DOUBLE_CONVERSION_HOME=/usr \
+ cmake \
+ -B build -S apache-${pkgname}-${pkgver}/cpp \
+ -DCMAKE_INSTALL_PREFIX="/usr" \
+ -DCMAKE_INSTALL_LIBDIR="lib" \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DARROW_BUILD_STATIC=OFF \
+ -DARROW_DEPENDENCY_SOURCE=SYSTEM \
+ -DARROW_BUILD_TESTS=ON \
+ -DARROW_COMPUTE=ON \
+ -DARROW_SUBSTRAIT=ON \
+ -DARROW_FLIGHT=ON \
+ -DARROW_FLIGHT_SQL=ON \
+ -DARROW_GANDIVA=OFF \
+ -DARROW_HDFS=ON \
+ -DARROW_IPC=ON \
+ -DARROW_JEMALLOC=ON \
+ -DARROW_ORC=ON \
+ -DARROW_PARQUET=ON \
+ -DARROW_PLASMA=ON \
+ -DARROW_PYTHON=ON \
+ -DARROW_TENSORFLOW=ON \
+ -DARROW_SIMD_LEVEL=AVX2 \
+ -DARROW_USE_GLOG=ON \
+ -DARROW_WITH_BROTLI=ON \
+ -DARROW_WITH_BZ2=ON \
+ -DARROW_WITH_LZ4=ON \
+ -DARROW_WITH_SNAPPY=ON \
+ -DARROW_WITH_ZLIB=ON \
+ -DARROW_WITH_ZSTD=ON \
+ -DPARQUET_REQUIRE_ENCRYPTION=ON
+ make -C build
+}
+
+check(){
+ PARQUET_TEST_DATA="${srcdir}"/parquet-testing/data \
+ ARROW_TEST_DATA="${srcdir}"/arrow-testing/data \
+ make -C build test
+}
+
+package(){
+ make -C build DESTDIR="${pkgdir}" install
+ find "${pkgdir}"/usr/lib/ -name '*testing*' -delete
+}
More information about the arch-commits
mailing list