[arch-commits] Commit in qgis/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, June 11, 2022 @ 15:51:13
  Author: foutrelis
Revision: 1233876

archrelease: copy trunk to community-staging-x86_64

Added:
  qgis/repos/community-staging-x86_64/
  qgis/repos/community-staging-x86_64/PKGBUILD
    (from rev 1233875, qgis/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: qgis/repos/community-staging-x86_64/PKGBUILD (from rev 1233875, qgis/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-11 15:51:13 UTC (rev 1233876)
@@ -0,0 +1,55 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Doug Newgard <scimmia at archlinux dot org>
+# Contributor: XavierCLL <xavier.corredor.llano (a) gmail.com>
+# Contributor: SaultDon <sault.don gmail>
+# Contributor: Lantald < lantald at gmx.com >
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
+# Contributor: Gerardo Exequiel Pozzi <vmlinuz386 at yahoo.com.ar>
+# Contributor: Eric Forgeot < http://esclinux.tk >
+
+pkgname=qgis
+pkgver=3.24.3
+pkgrel=2
+pkgdesc='Geographic Information System (GIS) that supports vector, raster & database formats'
+url='https://qgis.org/'
+license=('GPL')
+arch=('x86_64')
+depends=('exiv2' 'gdal' 'gsl' 'hicolor-icon-theme' 'libzip' 'ocl-icd' 'pdal' 'protobuf'
+         'python-gdal' 'python-jinja' 'python-owslib' 'python-psycopg2' 'python-pygments'
+         'python-qscintilla-qt5' 'python-yaml' 'qca' 'qt5-3d' 'qt5-imageformats'
+         'qt5-serialport' 'qt5-webkit' 'qtkeychain-qt5' 'qwt' 'spatialindex')
+makedepends=('cmake' 'fcgi' 'ninja' 'opencl-clhpp' 'python-setuptools' 'python-six' 'qt5-tools'
+             'txt2tags' 'sip' 'pyqt-builder')
+optdepends=('fcgi: Map server'
+            'gpsbabel: GPS Tools plugin')
+source=("https://qgis.org/downloads/$pkgname-$pkgver.tar.bz2"
+         qgstyle-infinite-loop.patch::https://github.com/qgis/QGIS/commit/19823b76.patch)
+sha256sums=('fc9fa28e10c32773f49f1de0c52a35a393060acd6f799d6926f08e96fbaf2b4e'
+            'c5bc388da987c7c21451b3f0f74220c8bd82cfba04657ff599d1896e6ae4b304')
+
+prepare() {
+  patch -d $pkgname-$pkgver -p1 < qgstyle-infinite-loop.patch # Fix infinite loop
+}
+
+build() {
+  cmake -S $pkgname-$pkgver -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX='/usr' \
+    -DWITH_3D=TRUE \
+    -DWITH_SERVER=TRUE \
+    -DWITH_CUSTOM_WIDGETS=TRUE \
+    -DBINDINGS_GLOBAL_INSTALL=TRUE \
+    -DQGIS_MANUAL_SUBDIR=share/man \
+    -DWITH_QWTPOLAR=TRUE \
+    -DQWTPOLAR_LIBRARY=/usr/lib/libqwt.so \
+    -DQWTPOLAR_INCLUDE_DIR=/usr/include/qwt \
+    -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DQWT_POLAR_VERSION=0x060200" \
+    -DWITH_INTERNAL_QWTPOLAR=FALSE \
+    -DWITH_PDAL=TRUE
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 $pkgname-$pkgver/rpm/sources/qgis-mime.xml "$pkgdir/usr/share/mime/packages/qgis.xml"
+}