[arch-commits] Commit in snd/repos/community-x86_64 (PKGBUILD PKGBUILD)
David Runge
dvzrv at gemini.archlinux.org
Sat Jun 11 17:16:29 UTC 2022
Date: Saturday, June 11, 2022 @ 17:16:29
Author: dvzrv
Revision: 1233943
archrelease: copy trunk to community-x86_64
Added:
snd/repos/community-x86_64/PKGBUILD
(from rev 1233942, snd/trunk/PKGBUILD)
Deleted:
snd/repos/community-x86_64/PKGBUILD
----------+
PKGBUILD | 208 +++++++++++++++++++++++++++++--------------------------------
1 file changed, 100 insertions(+), 108 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2022-06-11 17:16:17 UTC (rev 1233942)
+++ PKGBUILD 2022-06-11 17:16:29 UTC (rev 1233943)
@@ -1,108 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-# Contributor: Ray Rashif <schiv at archlinux.org>
-# Contributor: Juergen Hoetzel <juergen at archlinux.org>
-
-pkgname=snd
-pkgver=22.3
-pkgrel=1
-pkgdesc="An advanced sound editor"
-arch=(x86_64)
-url="https://ccrma.stanford.edu/software/snd/"
-license=(custom:free)
-groups=(pro-audio)
-depends=(glibc glu gmp gsl libglvnd libmpc libx11 libxext
-libxpm libxt mpfr openmotif)
-# TODO: maybe replace mpg123 with mpg321
-makedepends=(alsa-lib fftw flac gendesk jack ladspa libpulse
-libsamplerate mpg123 ruby speex timidity++ vorbis-tools wavpack)
-optdepends=(
- 'flac: For flac support'
- 'mpg123: For MPEG support'
- 'pulseaudio: For pulseaudio support'
- 'ruby: for snd-ruby'
- 'speex: For speex support'
- 'timidity++: For MIDI to WAVE support'
- 'vorbis-tools: For OGG support'
- 'wavpack: For wav support'
-)
-options=(debug)
-source=(https://sourceforge.net/projects/$pkgname/files/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
-sha512sums=('548f9cf3be2df28e66f51709b6ee078f951e4d8bbaf140a4e7b4b92bbe5f5d93a2343fe9857654efb09662ec5d063113db0204d6d4052f98c4d11e5fddc2c08c')
-b2sums=('eba03468e1512daa4ae33a56ad13ec76b7cf90e6a8e3822453bff1ad99b03fb0f0d12f94b29afe9697b6fe9a34fd2e00759c158cb413416ef4814d31a1c969a8')
-
-prepare() {
- gendesk -f -n \
- --pkgname "edu.stanford.ccrma.$pkgname-s7" \
- --name "$pkgname (s7)" \
- --exec "$pkgname-s7" \
- --genericname "Sound Editor" \
- --categories "AudioVideo;Audio"
- gendesk -f -n \
- --pkgname "edu.stanford.ccrma.$pkgname-ruby" \
- --name "$pkgname (ruby)" \
- --exec "$pkgname-ruby" \
- --genericname "Sound Editor" \
- --categories "AudioVideo;Audio"
- gendesk -f -n \
- --pkgname "edu.stanford.ccrma.$pkgname" \
- --name $pkgname \
- --exec $pkgname \
- --genericname "Sound Editor" \
- --categories "AudioVideo;Audio"
- rm -v $pkgname-$pkgver/*.desktop
- cp -av $pkgname-$pkgver $pkgname-ruby-$pkgver
-}
-
-build() {
- (
- cd $pkgname-$pkgver
- ./configure --prefix=/usr \
- --with-alsa \
- --with-gl \
- --with-gmp \
- --with-jack \
- --with-ladspa \
- --with-motif \
- --with-pulseaudio \
- --with-s7
- make
- )
- (
- cd $pkgname-ruby-$pkgver
- ./configure --prefix=/usr \
- --with-alsa \
- --with-gl \
- --with-gmp \
- --with-jack \
- --with-ladspa \
- --with-motif \
- --with-pulseaudio \
- --with-ruby
- make
- )
-}
-
-package() {
- depends+=(libasound.so libfftw3.so libjack.so libsamplerate.so)
-
- make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
- mv -v "$pkgdir/usr/bin/snd"{,-s7}
-
- make DESTDIR="$pkgdir" install -C $pkgname-ruby-$pkgver
- mv -v "$pkgdir/usr/bin/snd"{,-ruby}
-
- # set s7 version as default
- ln -sv snd-s7 "$pkgdir/usr/bin/snd"
-
- # XDG desktop integration
- install -vDm 644 *.desktop -t "$pkgdir/usr/share/applications/"
- # license
- install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
- # docs
- install -vDm 644 $pkgname-$pkgver/{{HISTORY,README}.Snd,NEWS} -t "$pkgdir/usr/share/doc/$pkgname/"
- install -vDm 644 $pkgname-$pkgver/*.html -t "$pkgdir/usr/share/doc/$pkgname/html"
- install -vDm 644 $pkgname-$pkgver/pix/*.png -t "$pkgdir/usr/share/doc/$pkgname/html/pix"
-
- # remove examples of unsupported extension language forth (not in the repos)
- rm -v "$pkgdir/usr/share/$pkgname/"*.fs
-}
Copied: snd/repos/community-x86_64/PKGBUILD (from rev 1233942, snd/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2022-06-11 17:16:29 UTC (rev 1233943)
@@ -0,0 +1,100 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+
+pkgname=snd
+pkgver=22.4
+pkgrel=1
+pkgdesc="An advanced sound editor"
+arch=(x86_64)
+url="https://ccrma.stanford.edu/software/snd/"
+license=(custom:free)
+groups=(pro-audio)
+depends=(glibc glu gmp gsl libglvnd libmpc libx11 libxext
+libxpm libxt mpfr openmotif)
+# TODO: maybe replace mpg123 with mpg321
+makedepends=(alsa-lib fftw flac gendesk jack ladspa libsamplerate mpg123 ruby
+speex timidity++ vorbis-tools wavpack)
+optdepends=(
+ 'flac: For flac support'
+ 'mpg123: For MPEG support'
+ 'ruby: for snd-ruby'
+ 'speex: For speex support'
+ 'timidity++: For MIDI to WAVE support'
+ 'vorbis-tools: For OGG support'
+ 'wavpack: For wav support'
+)
+options=(debug)
+source=(https://sourceforge.net/projects/$pkgname/files/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
+sha512sums=('b6be7af7545fc53de0c3fe6496cc78f44f36842571b82dc04494cc598ad734ea3f18cde370efa26fb38e9866e34c5085c6176ff8bee53c5e90fea6ace399fdf3')
+b2sums=('f5e004e7122db40fa74d4c2abeace180c7b3f37143278fe8212d0e414fb967961ecb39e3abb461ca9fb286393253b2e413f6cbc717d93dfe50660aa96d2521fc')
+
+prepare() {
+ gendesk -f -n \
+ --pkgname "edu.stanford.ccrma.$pkgname-s7" \
+ --name "$pkgname (s7)" \
+ --exec "$pkgname-s7" \
+ --genericname "Sound Editor" \
+ --categories "AudioVideo;Audio"
+ gendesk -f -n \
+ --pkgname "edu.stanford.ccrma.$pkgname-ruby" \
+ --name "$pkgname (ruby)" \
+ --exec "$pkgname-ruby" \
+ --genericname "Sound Editor" \
+ --categories "AudioVideo;Audio"
+ gendesk -f -n \
+ --pkgname "edu.stanford.ccrma.$pkgname" \
+ --name $pkgname \
+ --exec $pkgname \
+ --genericname "Sound Editor" \
+ --categories "AudioVideo;Audio"
+ rm -v $pkgname-$pkgver/*.desktop
+ cp -av $pkgname-$pkgver $pkgname-ruby-$pkgver
+}
+
+build() {
+ local options=(
+ --prefix=/usr
+ --with-alsa
+ --with-gl
+ --with-gmp
+ --with-jack
+ --with-ladspa
+ --with-motif
+ )
+ (
+ cd $pkgname-$pkgver
+ ./configure "${options[@]}" --with-s7
+ make
+ )
+ (
+ cd $pkgname-ruby-$pkgver
+ ./configure "${options[@]}" --with-ruby
+ make
+ )
+}
+
+package() {
+ depends+=(libasound.so libfftw3.so libjack.so libsamplerate.so)
+
+ make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
+ mv -v "$pkgdir/usr/bin/snd"{,-s7}
+
+ make DESTDIR="$pkgdir" install -C $pkgname-ruby-$pkgver
+ mv -v "$pkgdir/usr/bin/snd"{,-ruby}
+
+ # set s7 version as default
+ ln -sv snd-s7 "$pkgdir/usr/bin/snd"
+
+ # XDG desktop integration
+ install -vDm 644 *.desktop -t "$pkgdir/usr/share/applications/"
+ # license
+ install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
+ # docs
+ install -vDm 644 $pkgname-$pkgver/{{HISTORY,README}.Snd,NEWS} -t "$pkgdir/usr/share/doc/$pkgname/"
+ install -vDm 644 $pkgname-$pkgver/*.html -t "$pkgdir/usr/share/doc/$pkgname/html"
+ install -vDm 644 $pkgname-$pkgver/pix/*.png -t "$pkgdir/usr/share/doc/$pkgname/html/pix"
+
+ # remove examples of unsupported extension language forth (not in the repos)
+ rm -v "$pkgdir/usr/share/$pkgname/"*.fs
+}
More information about the arch-commits
mailing list