[arch-commits] Commit in wt/repos (2 files)

[Felix Yan]

    Date: Monday, June 13, 2022 @ 10:18:19
  Author: felixonmars
Revision: 1237386

archrelease: copy trunk to community-staging-x86_64

Added:
  wt/repos/community-staging-x86_64/
  wt/repos/community-staging-x86_64/PKGBUILD
    (from rev 1237385, wt/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: wt/repos/community-staging-x86_64/PKGBUILD (from rev 1237385, wt/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-13 10:18:19 UTC (rev 1237386)
@@ -0,0 +1,47 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Contributor: Denis Martinez <deuns.martinez at gmail.com>
+
+pkgname=wt
+pkgver=4.7.1
+pkgrel=2
+pkgdesc="a C++ library and application server for developing and deploying web applications"
+arch=('x86_64')
+url="http://www.webtoolkit.eu/"
+license=('GPL')
+depends=('boost-libs' 'libharu' 'graphicsmagick' 'pango' 'zlib' 'libgl' 'harfbuzz'
+         'qt5-base')
+makedepends=('boost' 'cmake' 'postgresql-libs' 'fcgi' 'sqlite' 'mysql++' 'doxygen'
+             'graphviz' 'mesa' 'glu' 'ninja')
+optdepends=('openssl: for SSL support in built-in webserver'
+	    'fcgi: for FastCGI support'
+	    'postgresql-libs: for PostgreSQL Dbo support'
+        'mariadb-libs: for MySQL Dbo support'
+	    'sqlite: for Sqlite Dbo support'
+	    'mysql++: for the hangman example')
+backup=('etc/wt/wt_config.xml')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/kdeforche/wt/archive/${pkgver}.tar.gz")
+sha512sums=('7678fdb8dd9ea013646a67a6d4d4a4e277cb1e2bea6e5e8407089d3d396f4236523b63387350836df89597f5e8ce19addf0df0dbbcc068eb87717b6e78aca88e')
+
+build() {
+  cd ${pkgname}-${pkgver}
+
+  cmake \
+      -Bbuild \
+      -GNinja \
+      -DCONNECTOR_HTTP=ON \
+      -DWT_WRASTERIMAGE_IMPLEMENTATION=GraphicsMagick \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DWEBUSER=http \
+      -DWEBGROUP=http \
+      -DUSE_SYSTEM_SQLITE3=ON \
+      -DINSTALL_EXAMPLES=ON \
+      -DBUILD_EXAMPLES=ON
+  ninja -C build
+}
+
+package() {
+  cd "$srcdir"/${pkgname}-${pkgver}
+
+  DESTDIR="$pkgdir" ninja -C build install
+}