[arch-commits] Commit in wesnoth/repos (2 files)

[Felix Yan]

    Date: Monday, June 13, 2022 @ 10:22:04
  Author: felixonmars
Revision: 1237395

archrelease: copy trunk to community-staging-x86_64

Added:
  wesnoth/repos/community-staging-x86_64/
  wesnoth/repos/community-staging-x86_64/PKGBUILD
    (from rev 1237394, wesnoth/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: wesnoth/repos/community-staging-x86_64/PKGBUILD (from rev 1237394, wesnoth/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-13 10:22:04 UTC (rev 1237395)
@@ -0,0 +1,47 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+# Contributor: Jacobo Arvelo <unix4all at ya.com>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+
+pkgname=wesnoth
+# NOTE: Odd minor versions are unstable! Do not package those.
+pkgver=1.16.3
+epoch=1
+pkgrel=2
+pkgdesc="A turn-based strategy game on a fantasy world"
+arch=('x86_64')
+license=('GPL')
+url="http://www.wesnoth.org/"
+depends=('sdl2_mixer' 'sdl2_image' 'boost-libs' 'pango' 'dbus')
+makedepends=('boost' 'cmake' 'git' 'ninja')
+replaces=('wesnoth-data')
+options=(!emptydirs)
+source=("git+https://github.com/wesnoth/wesnoth.git#tag=${pkgver}")
+sha512sums=('SKIP')
+
+build() {
+  cd "$pkgname"
+
+  cmake \
+      -GNinja \
+      -Bbuild \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DENABLE_TOOLS=ON \
+      -DFIFO_DIR=/run/wesnothd \
+      -DENABLE_DISPLAY_REVISION=OFF
+  ninja -C build
+}
+
+package() {
+  cd "$pkgname"
+
+  DESTDIR="$pkgdir" ninja -C build install
+
+  # See http://forums.wesnoth.org/viewtopic.php?t=51038
+  echo "Linux repository" > "$pkgdir"/usr/share/wesnoth/data/dist
+
+  mkdir -p "$pkgdir"/usr/lib/{tmpfiles.d,systemd/system}
+  sed "s|@FIFO_DIR@|/run/wesnothd|" packaging/systemd/wesnothd.tmpfiles.conf.in > "$pkgdir"/usr/lib/tmpfiles.d/wesnothd.conf
+  sed -e "s|@FIFO_DIR@|/run/wesnothd|" -e "s|@BINARY_SUFFIX@||" -e "s|@CMAKE_INSTALL_FULL_BINDIR@|/usr/bin|" packaging/systemd/wesnothd.service.in > "$pkgdir"/usr/lib/systemd/system/wesnothd.service
+}