[arch-commits] Commit in cryfs/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Mon Jun 13 10:47:58 UTC 2022
Date: Monday, June 13, 2022 @ 10:47:57
Author: felixonmars
Revision: 1237425
archrelease: copy trunk to community-staging-x86_64
Added:
cryfs/repos/community-staging-x86_64/
cryfs/repos/community-staging-x86_64/PKGBUILD
(from rev 1237424, cryfs/trunk/PKGBUILD)
----------+
PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
1 file changed, 38 insertions(+)
Copied: cryfs/repos/community-staging-x86_64/PKGBUILD (from rev 1237424, cryfs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-06-13 10:47:57 UTC (rev 1237425)
@@ -0,0 +1,38 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+# Contributor: kaylyn
+# Contributor: Giuseppe Calà <jiveaxe at gmail.com>
+
+pkgname=cryfs
+pkgver=0.11.2
+pkgrel=3
+pkgdesc='Cryptographic filesystem for the cloud'
+arch=(x86_64)
+depends=(fuse2 curl spdlog fmt boost-libs)
+makedepends=(cmake python boost range-v3)
+url='https://www.cryfs.org'
+license=(LGPL3)
+source=(https://github.com/cryfs/cryfs/releases/download/$pkgver/cryfs-$pkgver.tar.xz{,.asc})
+sha256sums=('951ef565d37521df5586b00ed898f1cb76188739c27b9db866cc91ca14fdf1bd'
+ 'SKIP')
+validpgpkeys=(5D5EC7BC6F1443EC2AF7177A9E6C996C991D25E1) # CryFS Team <messmer at cryfs.org>
+
+prepare() {
+ sed -e '/Release/d' -i doc/CMakeLists.txt # Install man page also with dafault build type
+}
+
+build() {
+ cmake -B build -S . \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DBUILD_TESTING=OFF \
+ -DCRYFS_UPDATE_CHECKS=OFF \
+ -DDEPENDENCY_CONFIG="cmake-utils/DependenciesFromLocalSystem.cmake"
+ cmake --build build
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --install build
+
+ install -Dm 644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+ install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
+}
More information about the arch-commits
mailing list