[arch-commits] Commit in grcov/repos (community-x86_64 community-x86_64/PKGBUILD)

[Orhun Parmaksiz]

    Date: Monday, June 13, 2022 @ 21:11:16
  Author: orhun
Revision: 1237828

archrelease: copy trunk to community-x86_64

Added:
  grcov/repos/community-x86_64/
  grcov/repos/community-x86_64/PKGBUILD
    (from rev 1237827, grcov/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: grcov/repos/community-x86_64/PKGBUILD (from rev 1237827, grcov/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2022-06-13 21:11:16 UTC (rev 1237828)
@@ -0,0 +1,37 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Contributor: Sanpi <sanpi+aur at homecomputing.fr>
+
+pkgname=grcov
+pkgver=0.8.10
+pkgrel=2
+pkgdesc="Rust tool to collect and aggregate code coverage data for multiple source files"
+arch=('x86_64')
+url="https://github.com/mozilla/grcov"
+license=('MPL2')
+depends=('zlib' 'gcc-libs')
+makedepends=('cargo')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('971efeccb23e8d6c397bcf71cf887e982dc48a3c199fb88e847de81a9c378df4')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release --frozen
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  cargo test --frozen --lib
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+}
+
+# vim: ts=2 sw=2 et: