[arch-commits] Commit in qt6-declarative/repos (2 files)

[Antonio Rojas]

    Date: Tuesday, June 14, 2022 @ 17:44:06
  Author: arojas
Revision: 448645

archrelease: copy trunk to testing-x86_64

Added:
  qt6-declarative/repos/testing-x86_64/
  qt6-declarative/repos/testing-x86_64/PKGBUILD
    (from rev 448644, qt6-declarative/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: qt6-declarative/repos/testing-x86_64/PKGBUILD (from rev 448644, qt6-declarative/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-06-14 17:44:06 UTC (rev 448645)
@@ -0,0 +1,44 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=qt6-declarative
+_qtver=6.3.1
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Classes for QML and JavaScript languages'
+depends=(qt6-base)
+makedepends=(cmake ninja python at-spi2-core qt6-shadertools qt6-languageserver)
+optdepends=('qt6-languageserver: for qmlls')
+conflicts=(qt6-quickcontrols2)
+provides=(qt6-quickcontrols2)
+replaces=(qt6-quickcontrols2)
+groups=(qt6)
+options=(debug)
+_pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
+source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
+sha256sums=('03e7694123820fcca397f95ce312e0b7f3039493c8754c836da098a1a04346e8')
+
+build() {
+  export CXXFLAGS+=" -ffat-lto-objects"
+  cmake -B build -S $_pkgfn -G Ninja \
+    -DINSTALL_PUBLICBINDIR=usr/bin
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+# Install symlinks for user-facing tools
+  cd "$pkgdir"
+  mkdir usr/bin
+  while read _line; do
+    ln -s $_line
+  done < "$srcdir"/build/user_facing_tool_links.txt
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
+}