[arch-commits] Commit in zstd/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Maxime Gauduin]

    Date: Thursday, June 16, 2022 @ 09:56:35
  Author: alucryd
Revision: 448795

archrelease: copy trunk to testing-x86_64

Added:
  zstd/repos/testing-x86_64/
  zstd/repos/testing-x86_64/PKGBUILD
    (from rev 448794, zstd/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: zstd/repos/testing-x86_64/PKGBUILD (from rev 448794, zstd/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-06-16 09:56:35 UTC (rev 448795)
@@ -0,0 +1,58 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
+# Contributor: Johan Förberg <johan at forberg.se>
+
+pkgname=zstd
+pkgver=1.5.2
+pkgrel=6
+pkgdesc='Zstandard - Fast real-time compression algorithm'
+url='https://facebook.github.io/zstd/'
+arch=(x86_64)
+license=(BSD GPL2)
+depends=(glibc gcc-libs zlib xz lz4)
+makedepends=(cmake gtest ninja)
+provides=(libzstd.so)
+options=(debug staticlibs)
+source=(https://github.com/facebook/zstd/releases/download/v${pkgver}/zstd-${pkgver}.tar.zst{,.sig})
+sha256sums=('3ea06164971edec7caa2045a1932d757c1815858e4c2b68c7ef812647535c23f'
+            'SKIP')
+b2sums=('513e4526a92bcb59416b3457d186a30e554f9e0cf21d7114eb3e9fbcbd9d662c8d95cf0b06237f6fe3f756862c63de0aa146d6a23cb4111c16e6459608d115f1'
+        'SKIP')
+validpgpkeys=(4EF4AC63455FC9F4545D9B7DEF8FE99528B52FFD)
+
+build() {
+  export CFLAGS+=' -ffat-lto-objects'
+  export CXXFLAGS+=' -ffat-lto-objects'
+  cmake -S ${pkgname}-${pkgver}/build/cmake -B build-shared -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DZSTD_BUILD_CONTRIB=ON \
+    -DZSTD_BUILD_STATIC=OFF \
+    -DZSTD_BUILD_TESTS=OFF \
+    -DZSTD_PROGRAMS_LINK_SHARED=ON
+  cmake --build build-shared
+  cmake -S ${pkgname}-${pkgver}/build/cmake -B build-static -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DZSTD_BUILD_CONTRIB=ON \
+    -DZSTD_BUILD_STATIC=ON \
+    -DZSTD_BUILD_TESTS=ON \
+    -DZSTD_PROGRAMS_LINK_SHARED=OFF
+  cmake --build build-static
+}
+
+check() {
+  cd build-static/tests
+  ctest
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build-shared
+  ln -sf /usr/bin/zstd "${pkgdir}/usr/bin/zstdmt"
+  install -Dm 644 ${pkgname}-${pkgver}/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: