[arch-commits] Commit in qt6-positioning/repos (2 files)

[Antonio Rojas]

    Date: Thursday, June 16, 2022 @ 16:49:11
  Author: arojas
Revision: 448816

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  qt6-positioning/repos/kde-unstable-x86_64/
  qt6-positioning/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 448815, qt6-positioning/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: qt6-positioning/repos/kde-unstable-x86_64/PKGBUILD (from rev 448815, qt6-positioning/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2022-06-16 16:49:11 UTC (rev 448816)
@@ -0,0 +1,35 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=qt6-positioning
+_qtver=6.4.0-beta1
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Provides access to position, satellite and area monitoring classes'
+depends=(qt6-base)
+makedepends=(cmake ninja qt6-declarative qt6-serialport)
+optdepends=('qt6-declarative: QML bindings' 'qt6-serialport: NMEA plugin')
+conflicts=(qt6-location)
+provides=(qt6-location)
+replaces=(qt6-location)
+groups=(qt6)
+options=(debug)
+_pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
+source=(https://download.qt.io/development_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
+sha256sums=('2b6ebe8176187d124b8025bfa107978823d79371e21997fe7fb5da8a3a754b9a')
+
+build() {
+  cmake -B build -S $_pkgfn -G Ninja \
+    -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
+}