[arch-commits] Commit in lib32-alsa-plugins/repos (2 files)

[David Runge]

    Date: Friday, June 17, 2022 @ 16:58:27
  Author: dvzrv
Revision: 1238318

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-alsa-plugins/repos/multilib-staging-x86_64/
  lib32-alsa-plugins/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1238317, lib32-alsa-plugins/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: lib32-alsa-plugins/repos/multilib-staging-x86_64/PKGBUILD (from rev 1238317, lib32-alsa-plugins/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-06-17 16:58:27 UTC (rev 1238318)
@@ -0,0 +1,56 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+_name=alsa-plugins
+pkgname=lib32-alsa-plugins
+pkgver=1.2.7.1
+pkgrel=1
+pkgdesc="Additional ALSA plugins (32-bit)"
+arch=(x86_64)
+url="https://www.alsa-project.org"
+license=(LGPL2.1)
+depends=("alsa-plugins=1:$pkgver" lib32-alsa-lib lib32-glibc)
+makedepends=(lib32-dbus lib32-jack lib32-libavtp lib32-libpulse
+lib32-libsamplerate lib32-speexdsp)
+optdepends=(
+  'lib32-dbus: for maemo plugin'
+  'lib32-jack: for pcm_jack plugin'
+  'lib32-libavtp: for pcm_aaf plugin'
+  'lib32-libsamplerate: for rate_samplerate plugin'
+  'lib32-libpulse: for conf_pulse, ctl_pulse and pcm_pulse plugins'
+  'lib32-speexdsp: for pcm_speex and rate_speexrate plugins'
+)
+options=(debug)
+source=(https://www.alsa-project.org/files/pub/plugins/$_name-$pkgver.tar.bz2{,.sig})
+sha512sums=('437c05a7e0175594768fd6a9a6d1a158bb4a01a7de6a42c2bd468d9381e01b64d385ddfac7d87baf84fe13cb4e65dc24da643940f416d4b191c528728822d964'
+            'SKIP')
+b2sums=('6f7aa503eda879cd273f36a16eec702b4da9267a60835cb5acbbfe355a83b7ffa3e93eb6483c9946c1d0bcd845a8f574470e7b84c66f793d0d0c6c9883ad52ee'
+        'SKIP')
+validpgpkeys=('F04DF50737AC1A884C4B3D718380596DA6E59C91') # ALSA Release Team (Package Signing Key v1) <release at alsa-project.org>
+
+prepare() {
+  cd $_name-$pkgver
+  autoreconf -fiv
+}
+
+build() {
+  cd $_name-$pkgver
+
+  export CC='gcc -m32'
+  export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
+
+  ./configure \
+    --prefix=/usr \
+    --libdir=/usr/lib32 \
+    --sysconfdir=/etc \
+    --enable-maemo-plugin
+  make
+}
+
+package() {
+  depends+=(libasound.so)
+
+  make DESTDIR="$pkgdir" install -C $_name-$pkgver
+  rm -rv "$pkgdir"/{etc,usr/share}
+}
+# vim:set sw=2 et: