[arch-commits] Commit in sqlcipher/repos (2 files)
Levente Polyak
anthraxx at gemini.archlinux.org
Fri Jun 17 18:13:59 UTC 2022
Date: Friday, June 17, 2022 @ 18:13:59
Author: anthraxx
Revision: 1238332
archrelease: copy trunk to community-testing-x86_64
Added:
sqlcipher/repos/community-testing-x86_64/
sqlcipher/repos/community-testing-x86_64/PKGBUILD
(from rev 1238331, sqlcipher/trunk/PKGBUILD)
----------+
PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
Copied: sqlcipher/repos/community-testing-x86_64/PKGBUILD (from rev 1238331, sqlcipher/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2022-06-17 18:13:59 UTC (rev 1238332)
@@ -0,0 +1,59 @@
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Contributor: flu
+
+pkgname=sqlcipher
+pkgver=4.5.1
+pkgrel=2
+pkgdesc="SQLite extension that provides transparent 256-bit AES encryption of database files"
+arch=('x86_64')
+url="https://www.zetetic.net/sqlcipher/"
+license=('BSD')
+depends=('openssl' 'sqlite' 'tcl' 'readline' 'zlib')
+source=(https://www.zetetic.net/$pkgname/verify/$pkgver/$pkgname-$pkgver.zip{,.sig})
+validpgpkeys=('D83F5F9EB811D6E6B4A0D9C5D1FA3A2A97ED25C2') # Zetetic LLC <support at zetetic.net>
+sha256sums=('a0752977b0b0dcac0f2931a176d89e6ab19b49402ab60bd37582693b3162b25e'
+ 'SKIP')
+
+build() {
+ cd "${srcdir}"/$pkgname-$pkgver
+
+ export CPPFLAGS="$CPPFLAGS \
+ -DSQLITE_ENABLE_COLUMN_METADATA=1 \
+ -DSQLITE_ENABLE_UNLOCK_NOTIFY \
+ -DSQLITE_ENABLE_DBSTAT_VTAB=1 \
+ -DSQLITE_ENABLE_FTS3_TOKENIZER=1 \
+ -DSQLITE_SECURE_DELETE \
+ -DSQLITE_ENABLE_STMTVTAB \
+ -DSQLITE_MAX_VARIABLE_NUMBER=250000 \
+ -DSQLITE_MAX_EXPR_DEPTH=10000 \
+ -DSQLITE_ENABLE_MATH_FUNCTIONS"
+
+ export CFLAGS="$CFLAGS -DSQLITE_HAS_CODEC -DSQLITE_TEMP_STORE=2 -DSQLCIPHER_TEST"
+ export LDFLAGS="$LDFLAGS -lcrypto"
+
+ ./configure --prefix=/usr \
+ --enable-tempstore=yes \
+ --disable-static \
+ --enable-fts3 \
+ --enable-fts4 \
+ --enable-fts5 \
+ --enable-rtree \
+ --enable-json1
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+ make testfixture
+}
+
+check() {
+ cd "${srcdir}"/$pkgname-$pkgver
+ ./testfixture test/sqlcipher.test
+}
+
+package() {
+ cd "${srcdir}"/$pkgname-$pkgver
+
+ make DESTDIR="${pkgdir}" install
+
+ #license
+ install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/$pkgname/LICENSE
+}
More information about the arch-commits
mailing list